use hiera for service class osfamily if statements

this should give some more flexibility in the future.

data/Debian-family.yaml

@@ -0,0 +1,5 @@
+---
+# Defaults for Debian os family (eg. Debian, Ubuntu etc)
+
+prosody::service::hasstatus: ~
+prosody::service::restart: ~

data/OpenBSD-family.yaml

@@ -0,0 +1,5 @@
+---
+# Defaults for OpenBSD os family
+
+prosody::service::hasstatus: ~
+prosody::service::restart: ~

data/common.yaml

@@ -65,3 +65,6 @@ prosody::community_modules::ensure: present
 prosody::community_modules::path: /var/lib/prosody/modules
 prosody::community_modules::source: https://hg.prosody.im/prosody-modules/
 prosody::community_modules::type: hg
+
+prosody::service::hasstatus: false
+prosody::service::restart: '/usr/bin/prosodyctl reload'

hiera.yaml

@@ -7,5 +7,8 @@ hierarchy:
   - name: "osname"
     paths:
       - "os/%{facts.os.name}.yaml"
+  - name: "osfamily"
+    paths:
+      - "%{facts.os.family}-family.yaml"
   - name: common
     path: common.yaml

manifests/service.pp

@@ -1,29 +1,16 @@
 # == Class: prosody::service
-class prosody::service {
+class prosody::service(
+  Optional[Boolean] $hasstatus = undef,
+  Optional[String]  $restart   = undef,
+) {
+
   if $prosody::daemonize {
-    case $facts['os']['family'] {
-      'OpenBSD': {
-        service { 'prosody':
-          ensure  => running,
-          enable  => true,
-          require => Class[prosody::config],
-        }
-      }
-      'Debian': {
-        service { 'prosody':
-          ensure  => running,
-          enable  => true,
-          require => Class[prosody::config],
-        }
-      }
-      default: {
-        service { 'prosody' :
-          ensure    => running,
-          hasstatus => false,
-          restart   => '/usr/bin/prosodyctl reload',
-          require   => Class[prosody::config],
-        }
-      }
+    service { 'prosody':
+      ensure    => running,
+      enable    => true,
+      hasstatus => $hasstatus,
+      restart   => $restart,
+      require   => Class[prosody::config],
     }
   }
 }