app-eselect/eselect-repository: Bump to v14

Signed-off-by: Michał Górny <[email protected]>

app-eselect/eselect-repository/Manifest

@@ -1 +1,2 @@
 DIST eselect-repository-13.tar.gz 8914 BLAKE2B 57d11585f3ac1b279c99e6664fbb088e6eb09f8ef67496edf4c7aa82dcb154ad8d89f9b3337b87d15a7a19e59cd5c2359aa555266fbbb19478c0414ecae0ccd0 SHA512 76eb3f7c6e907d2355613548dfd9c55640d257bf4c89acf634e313228365f909f461b38acbdda21bc3ba1bd47ebb8be4d10ba93c4082e72c52896ddec0b25568
+DIST eselect-repository-14.tar.gz 8954 BLAKE2B 01cfe850a4ede31e28ef28c26093217691b1e77ac52c4fed3c2bffac9e066e7d298e34c88028fce996edcfb0f2efcc3799db7d70753e40455d455ad0dd68edf5 SHA512 dc5350aba4fe5b76b0d5cfdf267b34ea26f3d3e3c7ec3d523696fd2635a49f616297d2dc9efc6bb7ce2ebd9c87a4ad7f0f06f115da34c401ed6306e5be7ac687

app-eselect/eselect-repository/eselect-repository-14.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit python-single-r1
+
+DESCRIPTION="Manage repos.conf via eselect"
+HOMEPAGE="https://github.com/projg2/eselect-repository/"
+SRC_URI="
+	https://github.com/projg2/eselect-repository/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-admin/eselect
+	$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+	net-misc/wget
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+src_compile() {
+	MAKEARGS=(
+		PREFIX="${EPREFIX}/usr"
+		SYSCONFDIR="${EPREFIX}/etc"
+		SHAREDSTATEDIR="${EPREFIX}/var"
+		ESELECTDIR="${EPREFIX}/usr/share/eselect/modules"
+	)
+
+	emake "${MAKEARGS[@]}"
+	python_fix_shebang eselect-repo-helper
+}
+
+src_test() {
+	epytest
+}
+
+src_install() {
+	emake "${MAKEARGS[@]}" DESTDIR="${D}" install
+	einstalldocs
+}