bintray.gradle

apply plugin: 'com.jfrog.bintray'
apply plugin: 'com.github.dcendents.android-maven'

task sourcesJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier = 'sources'
}

task javadoc(type: Javadoc) {
    source = android.sourceSets.main.java.srcDirs
    classpath += configurations.compile
    classpath += project.files(android.getBootClasspath().join(File.pathSeparator))

    options {
        encoding "UTF-8"
        charSet 'UTF-8'
        author true
        version true
        links "http://docs.oracle.com/javase/7/docs/api"
        title project.desc
    }
    // Turn off doclint because JDK 8 is too strict
    // http://blog.joda.org/2014/02/turning-off-doclint-in-jdk-8-javadoc.html
    options.addStringOption('Xdoclint:none', '-quiet')

    // TODO #43: Figure out how to build with AAR dependencies
    // Gradle: error: package android.support.v4.util does not exist
    // Gradle: error: cannot find symbol class SimpleArrayMap
    failOnError false
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

bintray {
    user = project.BINTRAY_USER
    key = project.BINTRAY_KEY

    configurations = ['archives']
    publish = false
    pkg {
        repo = 'maven'
        name = project.ext.name
        desc = project.desc
        websiteUrl = project.websiteUrl
        issueTrackerUrl = project.issueTrackerUrl
        vcsUrl = project.vcsUrl
        licenses = ['Apache-2.0']
        publicDownloadNumbers = false
    }
}

install.repositories.mavenInstaller.pom.project {
    packaging 'aar'
    developers {
        developer {
            id "sdchang5566"
            name "Sheng-Dean Chang"
            email "sdchang5566@gmail.com"
        }
    }
}