Update to wpewebkit 2.28.x running on poky dunfell

.gitmodules

@@ -1,20 +1,20 @@
 [submodule "base-image/meta-openembedded"]
 	path = base-image/meta-openembedded
 	url = git://git.openembedded.org/meta-openembedded
-	branch = sumo
+	branch = dunfell 
 [submodule "base-image/poky"]
 	path = base-image/poky
 	url = git://git.yoctoproject.org/poky
-	branch = sumo
+	branch = dunfell
 [submodule "base-image/meta-raspberrypi"]
 	path = base-image/meta-raspberrypi
 	url = git://git.yoctoproject.org/meta-raspberrypi
-	branch = sumo
-[submodule "base-image/meta-gstreamer1.0"]
-	path = base-image/meta-gstreamer1.0
-	url = https://github.com/OSSystems/meta-gstreamer1.0
-	branch = sumo
+	branch = dunfell
+[submodule "base-image/meta-qt5"]
+	path = base-image/meta-qt5
+	url = https://github.com/meta-qt5/meta-qt5.git
+	branch = dunfell
 [submodule "base-image/meta-webkit"]
 	path = base-image/meta-webkit
 	url = https://github.com/Igalia/meta-webkit
-	branch = sumo
+	branch = master

base-image/meta-resin-wpe/conf/layer.conf

@@ -7,4 +7,4 @@ BBFILE_COLLECTIONS += "resin-wpe"
 BBFILE_PATTERN_resin-wpe := "^${LAYERDIR}/"
 BBFILE_PRIORITY_resin-wpe = "99"
 
-LAYERSERIES_COMPAT_resin-wpe = "sumo"
+LAYERSERIES_COMPAT_resin-wpe = "sumo thud warrior dunfell"

base-image/meta-resin-wpe/conf/samples/bblayers.conf.sample

@@ -12,7 +12,7 @@ BBLAYERS ?= " \
   ${TOPDIR}/../meta-raspberrypi \
   ${TOPDIR}/../meta-webkit \
   ${TOPDIR}/../meta-resin-wpe \
-  ${TOPDIR}/../meta-gstreamer1.0 \
+  ${TOPDIR}/../meta-qt5 \
   ${TOPDIR}/../meta-openembedded/meta-oe \
   ${TOPDIR}/../meta-openembedded/meta-python \
   "

base-image/meta-resin-wpe/conf/samples/local.conf.sample

@@ -32,18 +32,21 @@ DISTRO_FEATURES_append = " opengl wayland"
 IMAGE_FEATURES_append = " hwcodecs"
 
 # Use proprietary Broadcom OpenGL drivers and wpebackend-rdk
+MACHINE_FEATURES_remove = "vc4graphics"
 PREFERRED_PROVIDER_virtual/wpebackend = "wpebackend-rdk"
 PACKAGECONFIG_pn-wpebackend-rdk = "rpi"
 
 # Enable H.264 decoding in hardware
 IMAGE_INSTALL_append = " gstreamer1.0-omx"
 LICENSE_FLAGS_WHITELIST_append = " commercial"
 
-# Enable accelerated 2D HTML5 canvas
+# Enable accelerated 2D HTML5 canvas (cannot specify both glesv2 and opengl for cairo)
 PACKAGECONFIG_append_pn-cairo = " glesv2 egl"
+PACKAGECONFIG_remove_pn-cairo = " opengl"
 PACKAGECONFIG_append_pn-wpewebkit = " 2dcanvas"
 
 # Specify versions
-PREFERRED_VERSION_cog = "0.2.%"
-PREFERRED_VERSION_libwpe = "1.0.%"
-PREFERRED_VERSION_wpewebkit = "2.22.%"
+PREFERRED_VERSION_cog = "0.6.%"
+PREFERRED_VERSION_libwpe = "1.6.%"
+PREFERRED_VERSION_wpewebkit = "2.28.%"
+

base-image/meta-resin-wpe/recipes-browser/cog/cog.inc

@@ -0,0 +1,49 @@
+SUMMARY = "Cog is a small launcher designed for the WebKit WPE port. \
+           But it also allows to use the WebKit GTK port instead. \
+           Cog is small: provides no user interface, and is suitable \
+           to be used as a Web application container. Cog may be \
+           presented fullscreen depending on the WPE backend being used. \
+           "
+HOMEPAGE = "https://github.com/Igalia/cog"
+BUGTRACKER = "https://github.com/Igalia/cog/issues"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=bf1229cd7425b302d60cdb641b0ce5fb"
+
+# Depend on wpewebkit unless the webkitgtk packageconfig option is selected.
+DEPENDS = " \
+            ${@bb.utils.contains('PACKAGECONFIG', 'webkitgtk', 'webkitgtk', 'wpewebkit', d)} \
+            ${@bb.utils.contains('PACKAGECONFIG', 'fdo', 'wayland', '', d)} \
+            libsoup-2.4 glib-2.0 wayland-native wayland-protocols \
+            "
+
+DEPENDS_append_class-target = " \
+            ${@bb.utils.contains('PACKAGECONFIG', 'fdo', 'wayland-native', '', d)} \
+            "
+
+# At run-time cog package should depend on virtual/wpebackend unless webkitgtk+ is enabled.
+RDEPENDS_${PN} += "\
+    ${@bb.utils.contains('PACKAGECONFIG', 'webkitgtk', '', 'virtual/wpebackend', d)} \
+    xkeyboard-config \
+    "
+
+inherit cmake
+
+# Cog can work with any wpebackend.
+# But for using wpebackend-fdo this has to be enabled at build time.
+PREFERRED_PROVIDER_virtual/wpebackend ?= "wpebackend-fdo"
+PACKAGECONFIG ?= " ${@bb.utils.contains('PREFERRED_PROVIDER_virtual/wpebackend', 'wpebackend-fdo', 'fdo', '', d)} "
+
+# libcogplatform*.so are plugins that should go on the main package (not on -dev)
+# https://github.com/Igalia/cog/commit/758ed08555e8152a2becd2178d1f3a4ce6e67af9
+# Also libWPEBackend-default.so should go into the main package.
+FILES_SOLIBSDEV = "${libdir}/libcogcore*.so"
+FILES_${PN} += "${libdir}/libcogplatform*.so"
+INSANE_SKIP_${PN} = "dev-so"
+
+# Use WebKitGTK+ instead of WPEWebKit
+PACKAGECONFIG[webkitgtk] = "-DCOG_USE_WEBKITGTK=ON,-DCOG_USE_WEBKITGTK=OFF"
+# Expose remote control interface on system bus.
+PACKAGECONFIG[dbus] = "-DCOG_DBUS_SYSTEM_BUS=ON,-DCOG_DBUS_SYSTEM_BUS=OFF"
+# Use wpebackend-fdo.
+PACKAGECONFIG[fdo] = "-DCOG_PLATFORM_FDO=ON,-DCOG_PLATFORM_FDO=OFF,wpebackend-fdo"
+PACKAGECONFIG[drm] = "-DCOG_PLATFORM_DRM=ON,-DCOG_PLATFORM_DRM=OFF,wpebackend-fdo libdrm virtual/libgbm libinput"

base-image/meta-resin-wpe/recipes-browser/cog/cog_0.6.0.bb

@@ -0,0 +1,8 @@
+require cog.inc
+
+SRC_URI = "https://github.com/Igalia/cog/releases/download/v${PV}/cog-${PV}.tar.xz"
+
+SRC_URI[md5sum] = "a97df4f0e2d25f4da7cd9bb55294d30e"
+SRC_URI[sha256sum] = "208f58e0533b269400875237a95e994c93da7234a29fd1c904e756b88963e35d"
+
+RDEPENDS_${PN} += "wpewebkit (>= 2.24)"

base-image/meta-resin-wpe/recipes-browser/wpewebkit/wpewebkit.inc

@@ -0,0 +1,109 @@
+SUMMARY = "WPE WebKit port pairs the WebKit engine with OpenGL-ES (OpenGL for Embedded Systems), \
+           allowing embedders to create simple and performant systems based on Web platform technologies. \
+           It is designed with hardware acceleration in mind, relying on EGL, and OpenGL ES."
+HOMEPAGE = "https://trac.webkit.org/wiki/WPE"
+BUGTRACKER = "https://bugs.webkit.org/"
+LICENSE = "BSD & LGPLv2+"
+LIC_FILES_CHKSUM = "file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 "
+
+DEPENDS = " \
+    bison-native gperf-native harfbuzz-native libxml2-native ccache-native ninja-native ruby-native cairo \
+    fontconfig freetype glib-2.0 gnutls harfbuzz icu jpeg pcre sqlite3 zlib libpng \
+    libsoup-2.4 libwebp libxml2 libxslt virtual/egl virtual/libgles2 libepoxy libgcrypt \
+"
+
+inherit cmake pkgconfig perlnative python3native
+inherit ${@'cmake_qt5' if 'qt5-layer' in d.getVar('BBFILE_COLLECTIONS').split() else ''}
+
+CCACHE_DISABLE[unexport] = "1"
+
+PACKAGECONFIG ??= "fetchapi indexeddb mediasource video webaudio webcrypto woff2 gst_gl remote-inspector openjpeg unified-builds"
+
+# WPE features
+PACKAGECONFIG[accessibility] = "-DENABLE_ACCESSIBILITY=ON,-DENABLE_ACCESSIBILITY=OFF,atk at-spi2-atk"
+PACKAGECONFIG[bubblewrap] = "-DENABLE_BUBBLEWRAP_SANDBOX=ON,-DENABLE_BUBBLEWRAP_SANDBOX=OFF,bubblewrap xdg-dbus-proxy bubblewrap-native xdg-dbus-proxy-native libseccomp"
+PACKAGECONFIG[developer-mode] = "-DDEVELOPER_MODE=ON,-DDEVELOPER_MODE=OFF,wayland-native wayland-protocols wpebackend-fdo"
+PACKAGECONFIG[deviceorientation] = "-DENABLE_DEVICE_ORIENTATION=ON,-DENABLE_DEVICE_ORIENTATION=OFF,"
+PACKAGECONFIG[encryptedmedia] = "-DENABLE_ENCRYPTED_MEDIA=ON,-DENABLE_ENCRYPTED_MEDIA=OFF,libgcrypt"
+PACKAGECONFIG[fetchapi] = "-DENABLE_FETCH_API=ON,-DENABLE_FETCH_API=OFF,"
+PACKAGECONFIG[gamepad] = "-DENABLE_GAMEPAD=ON,-DENABLE_GAMEPAD=OFF,"
+PACKAGECONFIG[geolocation] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue"
+PACKAGECONFIG[gst_gl] = "-DUSE_GSTREAMER_GL=ON,-DUSE_GSTREAMER_GL=OFF,gstreamer1.0-plugins-base"
+PACKAGECONFIG[indexeddb] = "-DENABLE_INDEXED_DATABASE=ON,-DENABLE_INDEXED_DATABASE=OFF,"
+PACKAGECONFIG[mediasource] = "-DENABLE_MEDIA_SOURCE=ON,-DENABLE_MEDIA_SOURCE=OFF,gstreamer1.0 gstreamer1.0-plugins-good"
+PACKAGECONFIG[service-worker] = "-DENABLE_SERVICE_WORKER=ON,-DENABLE_SERVICE_WORKER=OFF,"
+PACKAGECONFIG[video] = "-DENABLE_VIDEO=ON -DENABLE_VIDEO_TRACK=ON,-DENABLE_VIDEO=OFF -DENABLE_VIDEO_TRACK=OFF,gstreamer1.0 gstreamer1.0-plugins-base"
+PACKAGECONFIG[webaudio] = "-DENABLE_WEB_AUDIO=ON,-DENABLE_WEB_AUDIO=OFF,gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-good"
+PACKAGECONFIG[webcrypto] = "-DENABLE_WEB_CRYPTO=ON,-DENABLE_WEB_CRYPTO=OFF,libgcrypt libtasn1"
+PACKAGECONFIG[webgl2] = "-DENABLE_WEBGL2=ON,-DENABLE_WEBGL2=OFF,"
+PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2"
+# 2dcanvas requires cairo with opengl support. Try by setting in local.conf: PACKAGECONFIG_append_pn-cairo = " glesv2"
+PACKAGECONFIG[2dcanvas] = "-DENABLE_ACCELERATED_2D_CANVAS=ON,-DENABLE_ACCELERATED_2D_CANVAS=OFF,"
+PACKAGECONFIG[remote-inspector] = "-DENABLE_REMOTE_INSPECTOR=ON,-DENABLE_REMOTE_INSPECTOR=OFF,"
+PACKAGECONFIG[webrtc] = "-DENABLE_WEB_RTC=ON,-DENABLE_WEB_RTC=OFF,libvpx libevent libopus"
+PACKAGECONFIG[qtwpe] = "-DENABLE_WPE_QT_API=ON,-DENABLE_WPE_QT_API=OFF,qtbase-native qtbase qtdeclarative qtquickcontrols2 libepoxy wpebackend-fdo"
+PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg"
+PACKAGECONFIG[unified-builds] = "-DENABLE_UNIFIED_BUILDS=ON,-DENABLE_UNIFIED_BUILDS=OFF,"
+
+
+EXTRA_OECMAKE = " -DPORT=WPE -DCMAKE_BUILD_TYPE=Release -G Ninja"
+
+# If SSE code compiles, assume it runs successfully (it can't actually run
+# because of cross compiling)
+EXTRA_OECMAKE_append_x86 = " -DHAVE_SSE2_EXTENSIONS_EXITCODE=0"
+# mips/gold does not yet implement
+# error: .gnu.hash is incompatible with the MIPS ABI
+EXTRA_OECMAKE_append_mipsarch = " -DUSE_LD_GOLD=OFF "
+
+LDFLAGS_append_riscv64 = " -pthread"
+
+FULL_OPTIMIZATION_remove = "-g"
+
+LEAD_SONAME = "libWPEWebKit.so"
+PACKAGES =+ "${PN}-web-inspector-plugin ${PN}-qtwpe-qml-plugin"
+FILES_${PN} += "${libdir}/wpe-webkit*/injected-bundle/libWPEInjectedBundle.so"
+FILES_${PN}-web-inspector-plugin += "${libdir}/libWPEWebInspectorResources.so ${libdir}/wpe-webkit-*/libWPEWebInspectorResources.so"
+INSANE_SKIP_${PN}-web-inspector-plugin = "dev-so"
+
+FILES_${PN}-qtwpe-qml-plugin += "${libdir}/qt5/qml/org/wpewebkit/qtwpe/*"
+INSANE_SKIP_${PN}-qtwpe-qml-plugin = "dev-so"
+
+# JSC JIT on ARMv7 is better supported with Thumb2 instruction set.
+ARM_INSTRUCTION_SET_armv7a = "thumb"
+ARM_INSTRUCTION_SET_armv7r = "thumb"
+ARM_INSTRUCTION_SET_armv7m = "thumb"
+ARM_INSTRUCTION_SET_armv7ve = "thumb"
+
+# Extra runtime depends
+RDEPENDS_${PN} += " \
+    virtual/wpebackend \
+    ${@bb.utils.contains('PACKAGECONFIG', 'mediasource', 'gstreamer1.0-plugins-good-isomp4', '', d)} \
+    ${@bb.utils.contains('PACKAGECONFIG', 'webaudio', 'gstreamer1.0-plugins-good-wavparse', '', d)} \
+    ${@bb.utils.contains('PACKAGECONFIG', 'gst_gl', 'gstreamer1.0-plugins-base-opengl', '', d)} \
+    ${@bb.utils.contains('PACKAGECONFIG', 'video', 'gstreamer1.0-plugins-base-app \
+                                                    gstreamer1.0-plugins-base-playback \
+                                                    gstreamer1.0-plugins-base-audioconvert \
+                                                    gstreamer1.0-plugins-base-audioresample \
+                                                    gstreamer1.0-plugins-base-gio \
+                                                    gstreamer1.0-plugins-base-videoconvert \
+                                                    gstreamer1.0-plugins-base-videoscale \
+                                                    gstreamer1.0-plugins-base-volume \
+                                                    gstreamer1.0-plugins-base-typefindfunctions \
+                                                    gstreamer1.0-plugins-good-audiofx \
+                                                    gstreamer1.0-plugins-good-audioparsers \
+                                                    gstreamer1.0-plugins-good-autodetect \
+                                                    gstreamer1.0-plugins-good-avi \
+                                                    gstreamer1.0-plugins-good-deinterlace \
+                                                    gstreamer1.0-plugins-good-interleave \
+                                                    ', '', d)} \
+"
+
+# Extra runtime recommends
+RRECOMMENDS_${PN} += " \
+    ca-certificates \
+    shared-mime-info \
+    ttf-bitstream-vera \
+    ${PN}-web-inspector-plugin \
+    ${PN}-qtwpe-qml-plugin \
+    ${@bb.utils.contains('PACKAGECONFIG', 'video', 'gstreamer1.0-plugins-base-meta gstreamer1.0-plugins-good-meta gstreamer1.0-plugins-bad-meta', '', d)} \
+"

base-image/meta-resin-wpe/recipes-browser/wpewebkit/wpewebkit_2.28.2.bb

@@ -0,0 +1,12 @@
+require wpewebkit.inc
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+SRC_URI = "\
+    https://wpewebkit.org/releases/${BPN}-${PV}.tar.xz \
+"
+SRC_URI[md5sum] = "c1f17d4b031e9462692443e3c089789c"
+SRC_URI[sha256sum] = "6929d28744702ead3574484ca02645c457a6fdcd6b43ccc9766d98dc3664e8dc"
+
+DEPENDS += " libwpe"
+RCONFLICTS_${PN} = "libwpe (< 1.2) wpebackend-fdo (< 1.2)"
+

base-image/meta-resin-wpe/recipes-support/gnutls/gnutls_%.bbappend

@@ -0,0 +1,2 @@
+# We need to build GnuTLS with "system trust"
+EXTRA_OECONF += " --with-default-trust-store-dir=/etc/ssl/certs"

wpe-init

@@ -12,18 +12,11 @@ if [ -f /sys/class/backlight/rpi_backlight/brightness ]; then
 	echo $RPI_BACKLIGHT > /sys/class/backlight/rpi_backlight/brightness
 fi
 
-# Writable directories. See documentation here:
-# https://specifications.freedesktop.org/basedir-spec/basedir-spec-latest.html
-export HOME=/tmp/balena
-mkdir -p /tmp/balena/xdg_runtime
-chmod 0700 /tmp/balena/xdg_runtime
-export XDG_RUNTIME_DIR=/tmp/balena/xdg_runtime
-
 # Enable touch screen
 export WPE_BCMRPI_TOUCH=1
 
 # Start browser
-cog $WPE_URL &
+cog --cookie-store=always $WPE_URL &
 
 # Start Tohora
 ./tohora 8080 cog