Modular Gho Stewards

foundry.toml

@@ -12,4 +12,7 @@ extra_output_files = ["metadata"]
 optimizer = true
 optimizer_runs = 200
 
+[rpc_endpoints]
+mainnet = "${RPC_MAINNET}" 
+
 # See more config options https://github.com/foundry-rs/foundry/tree/master/config

src/contracts/facilitators/aave/interestStrategy/interfaces/IFixedRateStrategyFactory.sol

@@ -1,6 +1,11 @@
 // SPDX-License-Identifier: MIT
 pragma solidity ^0.8.0;
 
+/**
+ * @title IFixedRateStrategyFactory
+ * @author Aave Labs
+ * @notice Defines the interface of the FixedRateStrategyFactory
+ */
 interface IFixedRateStrategyFactory {
   /**
    * @dev Emitted when a new strategy is created

src/contracts/facilitators/gsm/feeStrategy/FixedFeeStrategyFactory.sol

@@ -0,0 +1,85 @@
+/// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.10;
+
+import {EnumerableSet} from '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';
+import {VersionedInitializable} from '@aave/core-v3/contracts/protocol/libraries/aave-upgradeability/VersionedInitializable.sol';
+import {IFixedFeeStrategyFactory} from './interfaces/IFixedFeeStrategyFactory.sol';
+import {IGsmFeeStrategy} from './interfaces/IGsmFeeStrategy.sol';
+import {FixedFeeStrategy} from './FixedFeeStrategy.sol';
+
+/**
+ * @title FixedFeeStrategyFactory
+ * @author Aave Labs
+ * @notice Factory contract to create and keep record of Gsm FixedFeeStrategy contracts
+ */
+contract FixedFeeStrategyFactory is VersionedInitializable, IFixedFeeStrategyFactory {
+  using EnumerableSet for EnumerableSet.AddressSet;
+
+  // Mapping of fee strategy contracts by buy and sell fees (buyFee => sellFee => feeStrategy)
+  mapping(uint256 => mapping(uint256 => address)) internal _gsmFeeStrategiesByFees;
+  EnumerableSet.AddressSet internal _gsmFeeStrategies;
+
+  /**
+   * @dev Initializer
+   * @param feeStrategiesList List of fee strategies
+   * @dev Assumes that the addresses provided are deployed FixedFeeStrategy contracts
+   */
+  function initialize(address[] memory feeStrategiesList) external initializer {
+    for (uint256 i = 0; i < feeStrategiesList.length; i++) {
+      address feeStrategy = feeStrategiesList[i];
+      uint256 buyFee = IGsmFeeStrategy(feeStrategy).getBuyFee(1e4);
+      uint256 sellFee = IGsmFeeStrategy(feeStrategy).getSellFee(1e4);
+
+      _gsmFeeStrategiesByFees[buyFee][sellFee] = feeStrategy;
+      _gsmFeeStrategies.add(feeStrategy);
+
+      emit FeeStrategyCreated(feeStrategy, buyFee, sellFee);
+    }
+  }
+
+  ///@inheritdoc IFixedFeeStrategyFactory
+  function createStrategies(
+    uint256[] memory buyFeeList,
+    uint256[] memory sellFeeList
+  ) external returns (address[] memory) {
+    require(buyFeeList.length == sellFeeList.length, 'INVALID_FEE_LIST');
+    address[] memory strategies = new address[](buyFeeList.length);
+    for (uint256 i = 0; i < buyFeeList.length; i++) {
+      uint256 buyFee = buyFeeList[i];
+      uint256 sellFee = sellFeeList[i];
+      address cachedStrategy = _gsmFeeStrategiesByFees[buyFee][sellFee];
+
+      if (cachedStrategy == address(0)) {
+        cachedStrategy = address(new FixedFeeStrategy(buyFee, sellFee));
+        _gsmFeeStrategiesByFees[buyFee][sellFee] = cachedStrategy;
+        _gsmFeeStrategies.add(cachedStrategy);
+
+        emit FeeStrategyCreated(cachedStrategy, buyFee, sellFee);
+      }
+
+      strategies[i] = cachedStrategy;
+    }
+
+    return strategies;
+  }
+
+  ///@inheritdoc IFixedFeeStrategyFactory
+  function getFixedFeeStrategies() external view returns (address[] memory) {
+    return _gsmFeeStrategies.values();
+  }
+
+  ///@inheritdoc IFixedFeeStrategyFactory
+  function getFixedFeeStrategy(uint256 buyFee, uint256 sellFee) external view returns (address) {
+    return _gsmFeeStrategiesByFees[buyFee][sellFee];
+  }
+
+  ///@inheritdoc IFixedFeeStrategyFactory
+  function REVISION() public pure virtual override returns (uint256) {
+    return 1;
+  }
+
+  /// @inheritdoc VersionedInitializable
+  function getRevision() internal pure virtual override returns (uint256) {
+    return REVISION();
+  }
+}

src/contracts/facilitators/gsm/feeStrategy/interfaces/IFixedFeeStrategyFactory.sol

@@ -0,0 +1,54 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+/**
+ * @title IFixedFeeStrategyFactory
+ * @author Aave Labs
+ * @notice Defines the interface of the FixedFeeStrategyFactory
+ */
+interface IFixedFeeStrategyFactory {
+  /**
+   * @dev Emitted when a new strategy is created
+   * @param strategy The address of the new Gsm fee strategy
+   * @param buyFee The buy fee of the new strategy
+   * @param sellFee The sell fee of the new strategy
+   */
+  event FeeStrategyCreated(
+    address indexed strategy,
+    uint256 indexed buyFee,
+    uint256 indexed sellFee
+  );
+
+  /**
+   * @notice Creates new Gsm Fee strategy contracts from lists of buy and sell fees
+   * @dev Returns the address of a cached contract if a strategy with same fees already exists
+   * @param buyFeeList The list of buy fees for Gsm fee strategies
+   * @param sellFeeList The list of sell fees for Gsm fee strategies
+   * @return The list of Gsm fee strategy contracts
+   */
+  function createStrategies(
+    uint256[] memory buyFeeList,
+    uint256[] memory sellFeeList
+  ) external returns (address[] memory);
+
+  /**
+   * @notice Returns all the fee strategy contracts of the factory
+   * @return The list of fee strategy contracts
+   */
+  function getFixedFeeStrategies() external view returns (address[] memory);
+
+  /**
+   * @notice Returns the fee strategy contract which corresponds to the given fees.
+   * @dev Returns `address(0)` if there is no fee strategy for the given fees
+   * @param buyFee The buy fee of the fee strategy contract
+   * @param sellFee The sell fee of the fee strategy contract
+   * @return The address of the fee strategy contract
+   */
+  function getFixedFeeStrategy(uint256 buyFee, uint256 sellFee) external view returns (address);
+
+  /**
+   * @notice Returns the GsmFeeStrategyFactory revision number
+   * @return The revision number
+   */
+  function REVISION() external pure returns (uint256);
+}