build.gradle

import org.jetbrains.dokka.gradle.DokkaTask
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

buildscript {
    repositories {
        google()
        gradlePluginPortal()
    }

    dependencies {
        classpath libs.android.gradlePlugin
        classpath libs.kotlin.gradlePlugin
        classpath libs.kotlin.serialization.plugin

        classpath libs.swaggerCodegen

        classpath libs.dokka
        classpath libs.spotless
        classpath libs.gradleVersionsPlugin
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

subprojects {
    afterEvaluate {
        if(it.hasProperty('android')) {
            android {
                compileSdkVersion 34

                defaultConfig {
                    minSdkVersion 21
                    targetSdkVersion 34
                }

                compileOptions {
                    sourceCompatibility JavaVersion.VERSION_17
                    targetCompatibility JavaVersion.VERSION_17
                }

                sourceSets['main'].java.srcDir('src/main/kotlin')
            }
        }
    }

    tasks.withType(KotlinCompile).configureEach {
        kotlinOptions {
            jvmTarget = JavaVersion.VERSION_17.toString()
        }
    }

    tasks.withType(DokkaTask).configureEach {
        dokkaSourceSets.configureEach {
            reportUndocumented.set(true)
            skipEmptyPackages.set(true)
            skipDeprecated.set(true)
            jdkVersion.set(17)

            // Add Android SDK packages
            noAndroidSdkLink.set(false)

            // AndroidX docs
            externalDocumentationLink {
                url.set(new URL("https://developer.android.com/reference/"))
                packageListUrl.set(new URL("https://developer.android.com/reference/androidx/package-list"))
            }
        }
    }

    // Exclude 'content' module as it contains generated code
    if (it.name != 'content') {
        apply from: "$rootDir/config/spotless.gradle"
    }
}

apply from: "$rootDir/config/dependencyUpdates.gradle"