configure.ac

dnl -*- mode: m4 -*-
AC_PREREQ(2.63)

AC_INIT([gnome-usage],
        [0.1],
        [],
        [gnome-usage])

AC_CONFIG_HEADERS(config.h)
AC_CONFIG_SRCDIR(src/main.vala)
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET

AM_INIT_AUTOMAKE([1.11 foreign tar-ustar dist-xz no-dist-gzip -Wno-portability])
AM_MAINTAINER_MODE([enable])
AM_SILENT_RULES([yes])

# i18n stuff
IT_PROG_INTLTOOL(0.40.0)

AM_GNU_GETTEXT([external])
AM_GNU_GETTEXT_VERSION([0.17])

GETTEXT_PACKAGE=AC_PACKAGE_NAME
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])

AC_PROG_CC
AC_PROG_INSTALL
AM_PROG_VALAC([0.21.1])
PKG_PROG_PKG_CONFIG([0.22])

AC_PROG_SED

## don't rerun to this point if we abort
AC_CACHE_SAVE

GLIB_GSETTINGS

# Resources
AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources)

# Mallard help
YELP_HELP_INIT

# pcap lib
LIBPCAP_CONFIG="pcap-config"
AC_MSG_CHECKING(libpcap)
if ! $LIBPCAP_CONFIG --libs > /dev/null 2>&1 ; then
  AC_MSG_ERROR(no)
else
  AC_MSG_RESULT(yes)
  LIBPCAP_LIBS="`$LIBPCAP_CONFIG --libs`"
  LIBPCAP_CFLAGS="`$LIBPCAP_CONFIG --cflags`"
fi

AC_SUBST([LIBPCAP_CFLAGS])
AC_SUBST([LIBPCAP_LIBS])

PKG_CHECK_MODULES(NETWORK_ANALYZER, [
    glib-2.0
    gio-2.0
    libnm-glib
    libnm-util
])

PKG_CHECK_MODULES(USAGE, [
    gtk+-3.0 >= 3.9.10
    libgtop-2.0
])

AC_CONFIG_FILES([
    Makefile
    network-analyzer/Makefile
    data/Makefile
    data/gnome-usage.desktop.in
    src/Makefile
    po/Makefile.in
])

AC_OUTPUT

echo "
    GNOME Usage $VERSION

    prefix:        ${prefix}
    sysconfdir:    ${sysconfdir}
    libexecdir:    ${libexecdir}
    Vala compiler: ${VALAC}
    C compiler:    ${CC}

    Now type 'make' to build $PACKAGE
"