build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    apply from: 'versions.gradle'
    addRepos(repositories)
    dependencies {
        classpath buildscriptDeps.dependencyUpdates
        classpath buildscriptDeps.gradle
        classpath buildscriptDeps.detekt
        classpath buildscriptDeps.kotlin
    }
}

apply from: rootProject.file('versions.gradle')
apply plugin: "io.gitlab.arturbosch.detekt"
apply from: rootProject.file('scripts/dependency_updates.gradle')

dependencies {
    detektPlugins "io.gitlab.arturbosch.detekt:detekt-formatting:$versions.detekt"
}

detekt {
    autoCorrect = true
    config = files("$rootDir/.detekt/detekt-config.yml")
    input = files("app/src", "core/src", "navigation/src", "navigation-debug/src", "reflection/src")
    parallel = true
    toolVersion = "$versions.detekt"
}

allprojects {
    apply from: rootProject.file('versions.gradle')
    addRepos(repositories)
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

// `./gradlew wrapper --gradle-version=[version]` uses the distribution type all
wrapper {
    distributionType = Wrapper.DistributionType.ALL
}