Language reference

Comments start with '#' and extend to the end of the line.

To include some other source file, use the special include comment (note the double-#, and no quotes around the file name):

Examples

## include foo.gs

Numbers are 64 bit signed integers. Numerical and string constants are given in a C-like way.

Examples

123
-456
0x4567
"Hi there\n"
'\033'
'\x1b'
'\u20ac'

Strings are not zero-terminated and can contain any data (including zeros). Use \xNN to set arbitray binary values. Use \uNNNN or \UNNNNNNNN to include UTF8-encoded Unicode characters.

Examples

"1 Euro = 1 €\n"
"1 Euro = 1 \u20ac\n"
"1 Euro = 1 \xe2\x82\xac\n"

Logical operations return values of type bool. They are not identical with integers.

Examples

true
false

There is a special value nil. It is not the same as 0.

Examples

nil

Primitive words

{ - start code block
- ( — code₁ )
Put a reference to the following code block on the stack. The code block starts after the opening { and extends to (and including) the matching closing }.

This special word is handled while converting the source code into binary code with gfxboot-compile. For this reason, this is the only word that cannot be redefined.
Examples
```
{ "Hello!" show }
```
See also: }, (, ), [, ], getdict, getparent, setdict, setparent
} - finish code block
- ( — )
This marks the end of a code block. When the code is executed, the interpreter leaves the current execution context and returns to the parent context.
Examples
```
/hello { "Hello!" show } def
hello                                # print "Hello!"
```
See also: {, (, ), [, ], getdict, getparent, setdict, setparent
( - start hash definition
- ( — mark₁ )
  
  mark₁: hash start marker
Put hash start marker on stack. Hash definition is completed with ).
Examples
```
( "foo" 10 "bar" 20 )        # hash with 2 keys "foo" and "bar"
```
See also: {, }, ), [, ], getdict, getparent, setdict, setparent
) - finish hash definition
- ( mark₁ any₁ … any_n — hash₁ )
  
  mark₁: array start marker
  
  any₁ … any_n: some key - value pairs
  
  hash₁: new hash
Search for mark₁ on the stack and put everything between mark₁ and TOS into a hash. The elements are interpreted alternatingly as key and value. If there’s an odd number of elements on the stack, the last value is nil.
Examples
```
( "foo" 10 "bar" 20 )        # hash with 2 keys "foo" and "bar"
```
See also: {, }, (, [, ], getdict, getparent, setdict, setparent
[ - start array definition
- ( — mark₁ )
  
  mark₁: array start marker
Put array start marker on stack. Array definition is completed with ].
Examples
```
[ 1 2 3 ]            # array with 3 elements
```
See also: {, }, (, ), ], getdict, getparent, setdict, setparent
] - finish array definition
- ( mark₁ any₁ … any_n — array₁ )
  
  mark₁: array start marker
  
  any₁ … any_n: some elements
  
  array₁: new array
Search for mark₁ on the stack and put everything between mark₁ and TOS into an array.
Examples
```
[ 10 20 "some" "text" ]      # array with 4 elements
```
See also: {, }, (, ), [, getdict, getparent, setdict, setparent
abs - absolute value
- ( int₁ — int₂ )
  
  int₂: |int₁|
- ( bool₁ — bool₂ )
  
  bool₂: bool₁
Absolute value of int₁ (change sign if int₁ is negative).
Examples
```
For boolean 1 bit arithmetic the value is unchanged.

-20 abs                      # 20
true abs                     # true
```
See also: add, and, div, max, min, mod, mul, neg, not, or, shl, shr, sub, xor
add - addition
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ + int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ xor bool₂
- ( array₁ array₂ — array₃ )
  
  array₃: array₂ appended to array₁
- ( hash₁ hash₂ — hash₃ )
  
  hash₃: joined hash₁ and hash₂
- ( string₁ string₂ — string₃ )
  
  string₃: string₂ appended to string₁
Add two numbers, or concatenate two arrays, or join two hashes, or concatenate two strings.

For boolean 1 bit arithmetic this is equivalent to 'xor'.
Examples
```
10 20 add                            # 30
true true add                        # false
[ 10 20 ] [ 30 40 ] add              # [ 10 20 30 40 ]
( "foo" 10 ) ( "bar" 20 ) add        # ( "bar" 20 "foo" 10 )
"abc" "def" add                      # "abcdef"
```
See also: abs, and, div, max, min, mod, mul, neg, not, or, shl, shr, sub, xor
and - and
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ and int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ and bool₂
Examples
```
15 4 and                     # 4
true false and               # false
```
See also: abs, add, div, max, min, mod, mul, neg, not, or, shl, shr, sub, xor
blt - copy rectangular region
- ( canvas₁ canvas₂ — )
Copy from the drawing region of canvas₂ to the drawing region of canvas₁, at the drawing pos of canvas₁ using the drawing mode of canvas₁.
Examples
```
# show cat picture

/cat_pic "cat.jpg" readfile unpackimage def
300 200 setpos getcanvas cat_pic blt
```
See also: dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
cmp - compare
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ <⇒ int₂
- ( bool₁ bool₂ — int₄ )
  
  int₄: bool₁ <⇒ bool₂
- ( string₁ string₂ — int₅ )
  
  int₅: string₁ <⇒ string₂
- ( any₁ any₂ — int₆ )
  
  int₆: any₁ <⇒ any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.

The result is -1, 1, 0 if the first argument is less than, greater than, or equal to the second argument, respectively.
Examples
```
10 20 cmp                    # -1
true false cmp               # 1
"abc" "abc" cmp              # 0
[ 10 20 ] [ 10 20 ] cmp      # varies
0 false cmp                  # varies
0 nil cmp                    # varies
"abc" [ 10 ] cmp             # varies

/foo [ 10 20 ] def
/bar foo def
foo bar cmp                  # 0
```
See also: eq, ge, gt, le, lt, ne
debug - start debug console
- ( — )
Stop code execution and start debug console.

You can leave (and re-enter) the debug console with ^D but note that this doesn’t resume program execution. Use the run (or r) console command for this.
Examples
```
/foo { debug 10 20 } def
foo                                  # activate debug console when 'foo' is run
```
See also: def, gdef, ldef
decodeutf8 - decode Unicode string
- ( string₁ — array₁ )
  
  string₁: UTF8-encoded string
  
  array₁: array with decoded chars
The array contains one element for each UTF8-encoded char. If string₁ contains non-UTF8-chars they are represented as the negated 8-bit value.
Examples
```
"ABC" decodeutf8                     # [ 65 66 67 ]
"Ä €" decodeutf8                     # [ 196 32 8364 ]
"A\xf0B" decodeutf8                  # [ 65 -240 66 ]
```
See also: encodeutf8, format, freeze, readfile, string
def - define new word
- ( word₁ any₁ — )
If word₁ does not exist, define word₁ in the current context.

If word₁ does already exist, redefine word₁ in the context in which it is defined.
Examples
```
/x 100 def           # define x as 100
/neg { -1 mul } def  # define a function that negates its argument
```
See also: debug, gdef, ldef
delete - delete an array, hash, or string element
- ( array₁ int₁ — )
  
  array₁: array to modify
  
  int₁: element index
- ( hash₁ string₁ — )
  
  hash₁: hash to modify
  
  string₁: key
- ( string₂ int₂ — )
  
  string₂: string to modify
  
  int₂: element index
Delete the respective element of array₁, hash₁, or string₂. The length of array₁ andstring_2 will be reduced by 1.

Note that string constants are read-only and cannot be modified.
Examples
```
/x [ 10 20 30 ] def
x 1 delete                           # x is now [ 10 30 ]

/y ( "foo" 10 "bar" 20 ) def
y "foo" delete                       # y is now ( "bar" 20 )

/z "ABC" mem def                     # mem is needed to create a writable copy
z 1 delete                           # z is now "AC"
```
See also: get, length, put
dim - get graphics object dimension
- ( canvas₁ — int₁ int₂ )
- ( font₁ — int₁ int₂ )
- ( canvas₁ — int₁ int₂ )
  
  int₁: width
  
  int₂: height
Get dimension of graphics object. For a canvas it is its size, for a fixed size font it is its glyph size, for proportional font the width is 0 and the height is the font height.
Examples
```
getconsole dim                         # 640 480
getconsole getfont dim                 # 8 16
```
See also: blt, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
div - division
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ / int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ / bool₂
Divide int₁ by int₂.

You can do a 1 bit division with boolean values. Note that this will run into a division by zero exception if bool₂ is false.
Examples
```
200 30 div                   # 6
true true div                # true
```
See also: abs, add, and, max, min, mod, mul, neg, not, or, shl, shr, sub, xor
drawline - draw line
- ( int₁ int₂ — )
  
  int₁: x
  
  int₂: y
Draw line from current position to the specified x and y coordinates using the current color. The drawing position is updated to the end position. Line segments outside the drawing region are not drawn.
Examples
```
100 200 drawline
```
See also: blt, dim, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
dup - duplicate TOS
- ( any₁ — any₁ any₁ )
Duplicate the top-of-stack element.
Examples
```
10 dup               # 10 10
```
See also: exch, index, over, pop, roll, rot
encodeutf8 - encode Unicode string
- ( array₁ — string₁ )
  
  array₁: array with decoded chars
  
  string₁: UTF8-encoded string
The array contains one element for each UTF8-encoded char. If string₁ should contain non-UTF8-chars they are represented as the negated 8-bit value in array₁.
Examples
```
[ 65 66 67 ] encodeutf8              # "ABC"
[ 196 32 8364 ] encodeutf8           # "Ä €"
[ 65 -240 66 ] encodeutf8            # "A\xf0B"
```
See also: decodeutf8, format, freeze, readfile, string
eq - equal
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ == bool₂
- ( int₁ int₂ — bool₄ )
  
  bool₄: int₁ == int₂
- ( string₁ string₂ — bool₅ )
  
  bool₅: string₁ == string₂
- ( any₁ any₂ — bool₆ )
  
  bool₆: any₁ == any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.
Examples
```
10 20 eq                     # false
true false eq                # false
"abc" "abc" eq               # true
[ 10 20 ] [ 10 20 ] eq       # false
0 false eq                   # false
0 nil eq                     # false
"abc" [ 10 ] eq              # false

/foo [ 10 20 ] def
/bar foo def
foo bar eq                   # true
```
See also: cmp, ge, gt, le, lt, ne
exch - swap upper two stack elements
- ( any₁ any₂ — any₂ any₁ )
Swap the two topmost stack elements.
Examples
```
10 20 exch            # 20 10
```
See also: dup, index, over, pop, roll, rot
exec - execute object
- ( ref₁ — )
  
  ref₁: word reference
- ( code₁ — )
  
  code₁: code block
Executes the given code block or looks up and executes the word reference.
Examples
```
{ 10 20 } exec                       # 10 20

/foo "abc" def
foo                                  # "abc"
/foo exec                            # "abc"
```
See also: exit, for, forall, loop, repeat, return, run
exit - leave loop/repeat/for/forall loop
- ( — )
Exit from current loop.
Examples
```
0 1 10 { dup 4 eq { exit } if } for          # 0 1 2 3 4
```
See also: exec, for, forall, if, ifelse, loop, repeat, return, run
fillrect - draw filled rectangle
- ( int₁ int₂ — )
  
  int₁: width
  
  int₂: height
Draw filled rectangle (using current color) at current position. The rectangle is clipped at the current drawing region.
Examples
```
200 100 fillrect
```
See also: blt, dim, drawline, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
for - run code block repeatedly, with counter
- ( int₁ int₂ int₃ code₁ — )
  
  int₁: start value
  
  int₂: increment value
  
  int₃: maximum value (inclusive)
Run code₁ repeatedly and put the current counter value on the stack in every iteration.

The counter starts with int₁ and is incremented by int₂ until it reaches int₃. The code block is executed with the start value and then as long as the counter is less than or equal to the maximum value.

The increment may be negative. In that case the loop is executed as long as the counter is greater than or equal to the maximum value.

If the increment is 0, the loop is not executed.
Examples
```
0 1 4 { } for                # 0 1 2 3 4
0 -2 -5 { } for              # 0 -2 -4
```
See also: exec, exit, forall, if, ifelse, loop, repeat, return, run
forall - loop over all elements
- ( array₁ code₁ — )
- ( hash₁ code₁ — )
- ( string₁ code₁ — )
Run code₁ for each element of array₁, hash₁, or string₁.

For array₁ and string₁, each element is put on the stack and code₁ is run.

For hash₁, each key and value pair are put on the stack and code₁ is run. The hash keys are iterated in alphanumerical order.

Note that string₁ is interpreted as a sequence of bytes, not UTF8-encoded characters.
Examples
```
[ 10 20 30 ] { } forall              # 10 20 30
( "foo" 10 "bar" 20 ) { } forall     # "bar" 20 "foo" 10
"ABC" { } forall                     # 65 66 67
```
See also: exec, exit, for, if, ifelse, loop, repeat, return, run
format - format string
- ( string₁ array₁ — string₂ )
  
  string₁: printf-style format string
  
  array₁: array with to-be-formatted arguments
  
  string₂: formatted string
Examples
```
"int = %d" [ 200 ] format            # "int = 200"
"string = %s" [ "foo" ] format       # "string = foo"
"%s: %d" [ "bar" 33 ] format         # "bar: 33"
```
See also: decodeutf8, encodeutf8, freeze, readfile, string
freeze - make object read-only
- ( any₁ — any₁ )
Make any object read-only. A read-only object cannot be modified.

Note that string constants are read-only by default.
Examples
```
[ 10 20 30 ] freeze                  # [ 10 20 30 ]
0 delete                             # raises 'readonly' exception
```
See also: decodeutf8, encodeutf8, format, readfile, string
gdef - define new global word
- ( word₁ any₁ — )
Define word₁ in the global context.
Examples
```
/foo 300 gdef        # define global word foo as 300
```
See also: debug, def, ldef
ge - greater or equal
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ >= bool₂
- ( int₁ int₂ — bool₄ )
  
  bool₄: int₁ >= int₂
- ( string₁ string₂ — bool₅ )
  
  bool₅: string₁ >= string₂
- ( any₁ any₂ — bool₆ )
  
  bool₆: any₁ >= any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.
Examples
```
10 20 ge                     # false
true false ge                # true
"abd" "abc" ge               # true
[ 10 20 ] [ 10 20 ] ge       # varies
0 false ge                   # varies
0 nil ge                     # varies
"abc" [ 10 ] ge              # varies
```
See also: cmp, eq, gt, le, lt, ne
get - get array, hash, or string element
- ( array₁ int₁ — )
  
  array₁: array to modify
  
  int₁: element index
- ( hash₁ string₁ — )
  
  hash₁: hash to modify
  
  string₁: key
- ( string₂ int₂ — )
  
  string₂: string to modify
  
  int₂: element index
Read the respective element of array₁, hash₁, or string₂.
Examples
```
[ 10 20 30 ] 2 get                   # 30
( "foo" 10 "bar" 20 ) "foo" get      # 10
"ABC" 1 get                          # 66
```
See also: delete, length, put
getbgcolor - get background color
- ( — int₁ )
  
  int₁: color
Return current background color.

A color is a RGB value with red in bits 16-23, green in bits 8-15 and blue in bits 0-7. This is independent of what the graphics card is actually using.
Examples
```
getcolor                             # 0 (black)
```
See also: blt, dim, drawline, fillrect, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getcanvas - get default canvas
- ( — canvas₁ )
- ( — nil )
Get default canvas used for graphics operations. If none has been set, return nil.

A canvas has associated - a size and position on screen (see 'getlocation') - a rectangular region used for drawing and clipping (see 'getregion') - a cursor position (see 'getpos') - a font (see 'getfont') - a color (see 'getcolor') - a background color - used in debug console (see 'getbgcolor') - a drawing mode (see 'getdrawmode')

+ .Examples
```
# get current default canvas

/current_canvas getcanvas def
```
+ See also: blt, dim, drawline, fillrect, getbgcolor, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getcolor - get drawing color
- ( — int₁ )
  
  int₁: color
Return current drawing color.

A color is a RGB value with red in bits 16-23, green in bits 8-15 and blue in bits 0-7. This is independent of what the graphics card is actually using.
Examples
```
getcolor                             # 0xffffff (white)
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getcompose - get compose list
- ( — array₁ )
- ( — nil )
Get current compose list. If none has been set, return nil.

The compose list is an array of graphics states.
Examples
```
/current_list getcompose def                   # get current list of visible graphics states
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getconsole - get debug console canvas
- ( — canvas₁ )
- ( — nil )
Get canvas of the debug console. If none has been set, return nil.
Examples
```
# get console font

/console_font getconsole getfont def
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getdict - get active dictionary
- ( — hash₁ )
- ( — nil )
  
  hash₁: dictionary
Return the currently active dictionary or nil, if the current context does not (yet) have a dictionary.

A dictionary will only be created on demand - that is, the first time a word is defined in the current context.

When a program is started the global context is created containing a dictionary with all primitive words.
Examples
```
/foo { getdict } def
foo                                  # nil

/bar { /x 10 ldef getdict } def
bar                                  # ( /x 10 )
```
See also: {, }, (, ), [, ], getparent, setdict, setparent
getdrawmode - get drawing mode
- ( — int₁ )
  
  int₁: drawing mode
Return drawing mode of current canvas.

Drawing mode is either 0 (merge mode) or 1 (direct mode).
Examples
```
getdrawmode                             # 0 ('merge' mode)
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getfont - get font
- ( canvas₁ — font₁ )
- ( canvas₁ — nil )
  
  canvas₁: canvas
  
  font₁: font
Get font used in canvas.
Examples
```
# get currently used font

getcanvas getfont
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getlocation - get location
- ( canvas₁ — int₁ int₂ )
  
  canvas₁: canvas
  
  int₁: x
  
  int₂: y
Get location associated with graphics state.
Examples
```
getcanvas getlocation                  # 0 0
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getparent - get parent of context, font, or hash
- ( context₁ — context₂ )
  
  context₂: parent of context₁ or nil
- ( font₁ — font₂ )
  
  font₂: parent of font₁ or nil
- ( hash₁ — hash₂ )
  
  hash₂: parent of hash₁ or nil
If a word lookup fails in a context, the lookup continues in the parent context.

If a glyph lookup fails in a font, the lookup continues in the parent font.

If a key cannot be found in a hash, the lookup continues in the parent hash.
Examples
```
/x ( "foo" 10 "bar" 20 ) def
/y ( "zap" 30 ) def
x getparent                          # nil
x y setparent
x getparent                          # ( "zap" 30 )
```
See also: {, }, (, ), [, ], getdict, setdict, setparent
getpixel - read pixel
- ( — int₁ )
- ( — nil )
  
  int₁: color
Read pixel at drawing position from canvas in current graphics state. If the position is outside the drawing region, return nil.
Examples
```
getpixel
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getpos - get drawing position
- ( — int₁ int₂ )
  
  int₁: x
  
  int₂: y
Return current drawing position. The position is relative to the drawing region in the graphics state.
Examples
```
getpos                               # 0 0
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
getregion - get drawing region
- ( canvas₁ — int₁ int₂ int₃ int₄ )
  
  canvas₁: canvas
  
  int₁: x
  
  int₂: y
  
  int₃: width
  
  int₄: height
Get drawing region associated with graphics state. Any drawing operation will be relative to this region. Graphics output will be clipped at the region boundaries.
Examples
```
getcanvas getregion                  # 0 0 800 600
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
gt - greater than
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ > bool₂
- ( int₁ int₂ — bool₄ )
  
  bool₄: int₁ > int₂
- ( string₁ string₂ — bool₅ )
  
  bool₅: string₁ > string₂
- ( any₁ any₂ — bool₆ )
  
  bool₆: any₁ > any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.
Examples
```
10 20 gt                     # false
true false gt                # true
"abd" "abc" gt               # true
[ 10 20 ] [ 10 20 ] gt       # varies
0 false gt                   # varies
0 nil gt                     # varies
"abc" [ 10 ] gt              # varies
```
See also: cmp, eq, ge, le, lt, ne
if - conditional execution
- (bool₁ code₁ — )
- (int₁ code₁ — )
- (nil code₁ — )
- (any₁ code₁ — )
  
  code₁: code block to run if condition evaluates to 'true'
The condition is false for: boolean false, integer 0, or nil. In all other cases it is true.
Examples
```
true { "ok" show } if        # "ok"
50 { "ok" show } if          # "ok"
nil { "ok" show } if         # shows nothing
"" { "ok" show } if          # "ok"
```
See also: exit, for, forall, ifelse, loop, repeat, return
ifelse - conditional execution
- (bool₁ code₁ code₂ — )
- (int₁ code₁ code₂ — )
- (nil code₁ code₂ — )
- (any₁ code₁ code₂ — )
  
  code₁: code block to run if condition evaluates to 'true'
  
  code₂: code block to run if condition evaluates to 'false'
The condition is false for: boolean false, integer 0, or nil. In all other cases it is true.
Examples
```
false { "ok" } { "bad" } ifelse show         # "bad"
20 { "ok" } { "bad" } ifelse show            # "ok"
nil { "ok" } { "bad" } ifelse sho            # "bad"
"" { "ok" } { "bad" } ifelse show            # "ok"
```
See also: exit, for, forall, if, loop, repeat, return
index - copy stack element
- ( any_n … any₀ int₁ — any_n … any₀ any_n )
  
  int₁: element position on stack (n is equal to int₁)
Copy the int₁-th-from-top element on the top-of-stack.
Examples
```
10 20 30 40 3 index          # 10 20 30 40 10

/dup { 0 index } def         # definition of 'dup'

/over { 1 index } def        # definition of 'over'
```
See also: dup, exch, over, pop, roll, rot
ldef - define new local word
- ( word₁ any₁ — )
Define word₁ in the current local context.
Examples
```
/foo 200 ldef        # define local word foo as 200
```
See also: debug, def, gdef
le - less or equal
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ ⇐ bool₂
- ( int₁ int₂ — bool₄ )
  
  bool₄: int₁ ⇐ int₂
- ( string₁ string₂ — bool₅ )
  
  bool₅: string₁ ⇐ string₂
- ( any₁ any₂ — bool₆ )
  
  bool₆: any₁ ⇐ any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.
Examples
```
10 20 le                     # true
true false le                # false
"abd" "abc" le               # false
[ 10 20 ] [ 10 20 ] le       # varies
0 false le                   # varies
0 nil le                     # varies
"abc" [ 10 ] le              # varies
```
See also: cmp, eq, ge, gt, lt, ne
length - get size of array, hash, or string
- ( array₁ — int₁ )
  
  int₁: number of elements in array₁
- ( hash₁ — int₂ )
  
  int₂: number of key - value pairs in hash₁
- ( string₁ — int₃ )
  
  int₃: number of bytes in string₁
Put the length of array₁, hash₁, or string₁ on the stack.
Examples
```
[ 10 20 30 ] length                  # 3
( "foo" 10 "bar" 20 ) length         # 2
"ABC" length                         # 3
```
See also: delete, get, put
loop - endless loop
- ( code₁ — )
Repeat code₁ forever until you exit the loop explicitly.
Examples
```
{ "Help!" show } loop
```
See also: exec, exit, for, forall, if, ifelse, repeat, return, run
lt - less than
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ < bool₂
- ( int₁ int₂ — bool₄ )
  
  bool₄: int₁ < int₂
- ( string₁ string₂ — bool₅ )
  
  bool₅: string₁ < string₂
- ( any₁ any₂ — bool₆ )
  
  bool₆: any₁ < any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.
Examples
```
10 20 lt                     # true
true false lt                # false
"abd" "abc" lt               # false
[ 10 20 ] [ 10 20 ] lt       # varies
0 false lt                   # varies
0 nil lt                     # varies
"abc" [ 10 ] lt              # varies
```
See also: cmp, eq, ge, gt, le, ne
max - maximum
- ( int₁ int₂ — int₃ )
  
  int₃: maximum(int₁, int₂)
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ or bool₂
  
  int₃ is the larger value of int₁ and int₂.
For boolean 1 bit arithmetic this is equivalent to 'or'
Examples
```
10 20 max                    # 20
true false max               # true
```
See also: abs, add, and, div, min, mod, mul, neg, not, or, shl, shr, sub, xor
min - minimum
- ( int₁ int₂ — int₃ )
  
  int₃: minimum(int₁, int₂)
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ and bool₂
  
  int₃ is the smaller value of int₁ and int₂.
For boolean 1 bit arithmetic this is equivalent to 'and'
Examples
```
10 20 min                    # 10
true false min               # false
```
See also: abs, add, and, div, max, mod, mul, neg, not, or, shl, shr, sub, xor
mod - remainder
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ % int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ / bool₂
  
  int₃ is the remainder dividing int₁ by int₂.
You can get the remainder from a 1 bit division with boolean values. Note that this will run into a division by zero exception if bool₂ is false.
Examples
```
200 30 mod                   # 20
true true mod                # false
```
See also: abs, add, and, div, max, min, mul, neg, not, or, shl, shr, sub, xor
mul - multiplication
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ * int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ and bool₂
Multiply int₁ by int₂.

For boolean 1 bit arithmetic this is equivalent to 'and'.
Examples
```
20 30 mul                    # 600
true false mul               # false
```
See also: abs, add, and, div, max, min, mod, neg, not, or, shl, shr, sub, xor
ne - not equal
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ != bool₂
- ( int₁ int₂ — bool₄ )
  
  bool₄: int₁ != int₂
- ( string₁ string₂ — bool₅ )
  
  bool₅: string₁ != string₂
- ( any₁ any₂ — bool₆ )
  
  bool₆: any₁ != any₂
For pairs of booleans, integers, and strings the values are compared. For all other combinations the internal object id is compared.
Examples
```
10 20 ne                     # true
true false ne                # true
"abc" "abc" ne               # false
[ 10 20 ] [ 10 20 ] ne       # true
0 false ne                   # true
0 nil ne                     # true
"abc" [ 10 ] ne              # true

/foo [ 10 20 ] def
/bar foo def
foo bar ne                   # false
```
See also: cmp, eq, ge, gt, le, lt
neg - negation
- ( int₁ — int₂ )
  
  int₂: -int₁
- ( bool₁ — bool₂ )
  
  bool₂: -bool₁
Negate int₁ (change sign).

For boolean 1 bit arithmetic the value is unchanged (this is not a 'not' operation).
Examples
```
20 neg                       # -20
true neg                     # true
```
See also: abs, add, and, div, max, min, mod, mul, not, or, shl, shr, sub, xor
newcanvas - create canvas
- ( int₁ int₂ — canvas₁ )
  
  int₁: width
  
  int₂: height
Create a new empty canvas of the specified size.
Examples
```
800 600 newcanvas
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
newfont - create font object
- ( string₁ — font₁ )
- ( string₁ — nil )
  
  string₁: font data
  
  font₁: font object
Parse font data in string₁ and create font object. If string₁ does not contain valid font data, return nil.
Examples
```
/foo_font "foo.fnt" readfile newfont def     # create font from file "foo.fnt"
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
not - not
- ( int₁ — int₂ )
  
  int₂: -int₁ - 1
- ( bool₁ — bool₂ )
  
  bool₂: !bool₁
Examples
```
20 not                       # -21
true not                     # false
```
See also: abs, add, and, div, max, min, mod, mul, neg, or, shl, shr, sub, xor
or - or
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ or int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ or bool₂
Examples
```
15 4 or                      # 15
true false or                # true
```
See also: abs, add, and, div, max, min, mod, mul, neg, not, shl, shr, sub, xor
over - copy TOS-1 to TOS
- ( any₁ any₂ — any₁ any₂ any₁ )
Put a copy of the second-from-top element on the top-of-stack.
Examples
```
10 20 over           # 10 20 10
```
See also: dup, exch, index, pop, roll, rot
pop - remove TOS
- ( any₁ — )
Remove the top-of-stack element.
Examples
```
10 20 pop            # 10
```
See also: dup, exch, index, over, roll, rot
put - set array, hash, or string element
- ( array₁ int₁ any₁ — )
  
  array₁: array to modify
  
  int₁: element index
  
  any₁: new value
- ( hash₁ string₁ any₂ — )
  
  hash₁: hash to modify
  
  string₁: key
  
  any₂: new value
- ( string₂ int₂ int₃ — )
  
  string₂: string to modify
  
  int₂: element index
  
  int₃: new value
Set the respective element of array₁, hash₁, or string₂.

Note that string constants are read-only and cannot be modified.
Examples
```
/x [ 10 20 30 ] def
x 2 40 put                           # x is now [ 10 20 40 ]

/y ( "foo" 10 "bar" 20 ) def
y "bar" 40 put                       # y is now ( "foo" 10 "bar" 40 )

/z "ABC" mem def                     # mem is needed to create a writable copy
z 1 68 put                           # z is now "ADC"
```
See also: delete, get, length
putpixel - set pixel
- ( — )
Set pixel with current color at drawing position in canvas in current graphics state. If the position is outside the drawing region, nothing is drawn.
Examples
```
setpixel
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
readfile - read file
- ( string₁ — string₂ )
- ( string₁ — nil )
  
  string₁: file name
  
  string₂: file content
Read entire file and return its content. If the file could not be read, return nil.
Examples
```
"foo" readfile
```
See also: decodeutf8, encodeutf8, format, freeze, string
repeat - repeat code block
- ( int₁ code₁ — )
Repeat code₁ int₁ times. If int₁ is less or equal to 0, code₁ is not run.
Examples
```
3 { "Help!" show } repeat            # "Help!Help!Help!"
```
See also: exec, exit, for, forall, if, ifelse, loop, return, run

return - leave current function

Exit from currently running function.

Examples

/foo { dup nil eq { return } if show } def
"abc" foo                                    # shows "abc"
nil foo                                      # does nothing

See also: exec, exit, for, forall, if, ifelse, loop, repeat, run

roll - rotate stack elements
- ( any₁ … any_n int₁ int₂ — any_x … any_y )
  
  int₁: number of stack elements to rotate (equal to index n)
  
  int₂: rotation amount
Rotate the n elements any₁ … any_n. The new positions are calculated as follows:

x = (1 - int₂) mod int₁

y = (n - int₂) mod int₁

This can be seen as rotating int₁ elements up by int₂ resp. down by -int₂.
Examples
```
10 20 30 40 50 5 2 roll      # 40 50 10 20 30

/rot { 3 -1 roll } def       # definition of 'rot'
```
See also: dup, exch, index, over, pop, rot
rot - rotate upper three stack elements
- ( any₁ any₂ any₃ — any₂ any₃ any₁ )
Rotate any₁ to the top-of-stack.
Examples
```
10 20 30 rot         # 20 30 10
```
See also: dup, exch, index, over, pop, roll
run - run code
- ( string₁ — )
  
  string₁: binary code
Load binary code and run it.

Note: unlike 'exec' this does not open a new context but replaces the currently running code with the new one.
Examples
```
"new_program" readfile run
```
See also: exec, exit, for, forall, loop, repeat, return
setbgcolor - set background color
- ( int₁ — )
  
  int₁: color
Set current background color.

A color is a RGB value with red in bits 16-23, green in bits 8-15 and blue in bits 0-7. This is independent of what the graphics card is actually using.
Examples
```
0xff00 setcolor                      # green
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
setcanvas - set default canvas
- ( canvas₁ — )
- ( nil — )
Set default canvas. If nil is passed, there will be no default canvas.
Examples
```
/saved_state getcanvas def                   # save current graphics state
...
saved_state setcanvas                        # restore saved graphics state
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
setcolor - set drawing color
- ( int₁ — )
  
  int₁: color
Set current drawing color.

A color is a RGB value with red in bits 16-23, green in bits 8-15 and blue in bits 0-7. This is independent of what the graphics card is actually using.
Examples
```
0xff0000 setcolor                    # red
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
setcompose - set compose list
- ( array₁ — )
- ( nil — )
Set current compose list. If nil is passed, the current list is removed.

The compose list is an array of canvas objects.
Examples
```
/saved_list getcompose def                   # save current list
...
saved_list setcompose                        # restore list
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
setconsole - set debug console canvas
- ( canvas₁ — )
- ( nil — )
Set canvas of the debug console. If nil is passed, the current canvas is removed (and debug console disabled).

You can use this to change the appearance of the debug console.
Examples
```
# change debug console backgound color to transparent light blue

getcanvas getconsole setcanvas 0x40405070 setbgcolor setcanvas
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
setdict - set active dictionary
- ( hash₁ — )
- ( nil — )
  
  hash₁: new active dictionary
Set the currently active dictionary. With nil, the dictionary is removed from the current context.
Examples
```
/foo { /x 10 ldef x } def
foo                                  # 10

/bar { ( /x 10 ) setdict x } def
bar                                  # 10
```
See also: {, }, (, ), [, ], getdict, getparent, setparent
setdrawmode - set drawing mode
- ( int₁ — )
  
  int₁: drawing mode
Set drawing mode if current canvas.

Drawing mode is either 0 (merge mode) or 1 (direct mode).
Examples
```
1 setdrawmode                           # set 'direct' mode
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setfont, setlocation, setpos, setregion, show, unpackimage, updatescreen
setfont - set font
- ( canvas₁ font₁ — )
- ( canvas₁ nil — )
  
  canvas₁: canvas
  
  font₁: font
Set font used in canvas. If nil is passed, no font will be associated with canvas.
Examples
```
# read font from file and use it

/foo_font "foo.fnt" readfile newfont def
getcanvas foo_font setfont
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setlocation, setpos, setregion, show, unpackimage, updatescreen
setlocation - set location
- ( canvas₁ int₁ int₂ — )
  
  canvas₁: canvas
  
  int₁: x
  
  int₂: y
Set location associated with graphics state.
Examples
```
getcanvas 10 10 setlocation
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setpos, setregion, show, unpackimage, updatescreen
setparent - set parent of context, font, or hash
- ( context₁ context₂ — )
- ( context₁ nil — )
  
  context₂: new parent of context₁
- ( font₁ font₂ — )
- ( font₁ nil — )
  
  font₂: new parent of font₁
- ( hash₁ hash₂ — )
- ( hash₁ nil — )
  
  hash₂: new parent of hash₁
If nil is used as second argument, any existing parent link is removed.

If a word lookup fails in a context, the lookup continues in the parent context.

If a glyph lookup fails in a font, the lookup continues in the parent font.

If a key cannot be found in a hash, the lookup continues in the parent hash.
Examples
```
/x ( "foo" 10 "bar" 20 ) def
/y ( "zap" 30 ) def
x "zap" get                          # nil
x y setparent
x "zap" get                          # 30
x nil setparent
x "zap" get                          # nil
```
See also: {, }, (, ), [, ], getdict, getparent, setdict
setpos - set drawing position
- ( int₁ int₂ — )
  
  int₁: x
  
  int₂: y
Set drawing position. The position is relative to the drawing region in the graphics state.
Examples
```
20 30 setpos
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setregion, show, unpackimage, updatescreen
setregion - set drawing region
- ( canvas₁ int₁ int₂ int₃ int₄ — )
  
  canvas₁: canvas
  
  int₁: x
  
  int₂: y
  
  int₃: width
  
  int₄: height
Set drawing region associated with graphics state. Any drawing operation will be relative to this region. Graphics output will be clipped at the region boundaries.
Examples
```
getcanvas 10 10 200 100 setregion
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, show, unpackimage, updatescreen
shl - shift left
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ << int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ and !bool₂
Examples
```
1 4 shl                      # 16
true false shl               # true
```
See also: abs, add, and, div, max, min, mod, mul, neg, not, or, shr, sub, xor
show - show
- ( string₁ — )
Print string₁ at current cursor position in canvas associated with current graphics state.

The cursor position is advanced to point at the end of the printed text. Newline ('\x0a') and carriage return ('\x0d') characters are interpreted and the cursor position is adjusted relative to the starting position.
Examples
```
"Hello!" show                        # print "Hello!"
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, unpackimage, updatescreen
shr - shift right
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ >> int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ and !bool₂
Examples
```
16 4 shr                     # 1
true false shr               # true
```
See also: abs, add, and, div, max, min, mod, mul, neg, not, or, shl, sub, xor
string - create or duplicate string
- ( int₁ — string₁ )
  
  int₁: length
  
  string₁: new string with length int₁
- ( string₂ — string₃ )
  
  string₂: string to duplicate
  
  string₃: copy of string₂
There are two variants: given a number, a string of that length is created and initialized with zeros; given a string, a copy of that string is created.

int₁ may be 0 to create a zero-length string.

Note: duplication works for all string-like objects. For example for word references and even code blocks.
Examples
```
2 string                    # creates an empty string of length 2: "\x00\x00"
"abc" string                # creates a copy of "abc"

# even this works:
/abc string                 # a copy of /abc
{ 10 20 } string            # a copy of the code block { 10 20 }
```
See also: decodeutf8, encodeutf8, format, freeze, readfile
sub - subtraction
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ - int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ xor bool₂
Subtract int₂ from int₁.

For boolean 1 bit arithmetic this is equivalent to 'xor'.
Examples
```
100 30 sub                   # 70
false true sub               # true
```
See also: abs, add, and, div, max, min, mod, mul, neg, not, or, shl, shr, xor
unpackimage - unpack image
- ( string₁ — canvas₁ )
- ( string₁ — nil )
  
  string₁: image file data
Unpacks image and returns a canvas object with the image or nil if the data does not contain image data.
Examples
```
"foo.jpg" readfile unpackimage
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, updatescreen
updatescreen - update screen region
- ( int₁ int₂ int₃ int₄ — )
  
  int₁: x
  
  int₂: y
  
  int₃: width
  
  int₄: height
Update (redraw) screen region.
Examples
```
10 10 200 100 updatescreen
```
See also: blt, dim, drawline, fillrect, getbgcolor, getcanvas, getcolor, getcompose, getconsole, getdrawmode, getfont, getlocation, getpixel, getpos, getregion, newcanvas, newfont, putpixel, setbgcolor, setcanvas, setcolor, setcompose, setconsole, setdrawmode, setfont, setlocation, setpos, setregion, show, unpackimage
xor - exclusive or
- ( int₁ int₂ — int₃ )
  
  int₃: int₁ xor int₂
- ( bool₁ bool₂ — bool₃ )
  
  bool₃: bool₁ xor bool₂
Examples
```
15 4 xor                     # 11
true false or                # true
```
See also: abs, add, and, div, max, min, mod, mul, neg, not, or, shl, shr, sub

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

reference.adoc

reference.adoc

Language reference

Primitive words

Files

reference.adoc

Latest commit

History

reference.adoc

File metadata and controls

Language reference

Primitive words