Union of contracts

[harris-chris]

Hello - am I right in thinking that it's not currently possible to express the idea in Nickel that a record might have one field, or another - like this?

let FromNum = {
    num | Number
} in

let FromPath = {
    local_path | String
} in

let Schema = {
    name | String
    , source | FromNum || FromPath
} in

{
    name = "foo"
    , source = { num = 1 }
} | Schema

I've read https://www.tweag.io/blog/2022-04-28-union-intersection-contracts/ but I'd like to double-check my understanding. If this is the case, is there an idiomatic work-around?

Thanks!

[vkleen]

It does indeed seem to be impossible to express this with fully lazy contracts, which record contracts in Nickel are supposed to be. Currently, the best workaround would be to write a custom contract that asserts that only one of the fields is present. So maybe something like

let FromNumOrPath = {
  num | Number | optional,
  local_path | String | optional
} in
let CheckNumXorPath = fun label value =>
  if std.record.has_field "num" value && std.record.has_field "local_path" value then
    std.contract.blame_with_message "either `num` or `local_path` but not both" label
  else if !std.record.has_field "num" value && ! std.record.has_field "local_path" value then
    std.contract.blame_with_message "either `num` or `local_path` must be set" label
  else
    value
in
let Schema = {
  name | String,
  source | FromNumOrPath | CheckNumXorPath,
} in {
  name = "foo",
  source = { num = 1 }
} | Schema

could work. But that's not particularly scalable or user friendly and we're actively trying to figure out a reasonable system. See for example #1533 and #1448. Note also, that we're having this exact problem with the JSON Schema to Nickel converter. Actually, that might lead to a slightly more scalable approach: write a JSON schema for this particular subcontract and then use the generated code. In essence that tool generates pretty much the code that I've written here, but it does it automatically.

EDIT: Actually check CheckNumXorPath and fixed a few typos

[harris-chris]

OK, thank you. I'd not thought of that work-around, and it's certainly not the ugliest work-around ever, so I'll use that until Nickel officially supports record contract unions.