build.gradle

plugins {
    id 'java'
    id "com.github.johnrengelman.shadow" version "7.1.2"
    id "maven-publish"
}

apply plugin: "com.github.johnrengelman.shadow"

group = 'com.pigumer.tools'
version = '0.1.0-SNAPSHOT'
sourceCompatibility = '11'
targetCompatibility = '11'
compileJava.options.encoding = 'UTF-8'
compileTestJava.options.encoding = 'UTF-8'
javadoc.options.encoding = 'UTF-8'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'commons-cli:commons-cli:1.5.0'
    implementation 'org.yaml:snakeyaml:1.30'
    implementation 'com.samskivert:jmustache:1.14'

    testImplementation(platform('org.junit:junit-bom:5.8.2'))
    testImplementation('org.junit.jupiter:junit-jupiter')
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

test {
    useJUnitPlatform()
}

jar {
    manifest {
        attributes "Main-Class": "com.pigumer.tools.cli.Main"
    }
}

task sourceJar(type: Jar) {
    classifier 'sources'
    from sourceSets.main.allJava
}

task javadocJar(type : Jar, dependsOn : javadoc) {
    classifier 'javadoc'
    from javadoc.destinationDir
}

publishing {
    publications {
        target(MavenPublication) {
            groupId group
            artifactId 'openapi-generator-util'
            version version
            from components.java
            artifact tasks.sourceJar
            artifact tasks.javadocJar
        }
    }
    repositories {
        maven {
            name = "GitHubPackages"
            url = "https://maven.pkg.github.com/takesection/openapi-generator-util"
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
}