build.gradle

plugins {
	id 'org.springframework.boot' version '3.0.6'
    id 'io.spring.dependency-management' version '1.1.0'
	id 'java'
    id 'eclipse'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

tasks.named('test') {
	useJUnitPlatform()
}

processResources {
    dependsOn 'metaProperties'
    from(new File(project.buildDir, "tmp")) {
        include 'version.properties'
    }
}

task metaProperties() {
    def output = new File(project.buildDir, "tmp/version.properties")
    outputs.file(output)
    doLast {
        def props = new Properties()
        props.setProperty("version", "${project.version}")
        props.store(output.newOutputStream(), null)
    }
}

eclipse {
    synchronizationTasks processResources
    classpath {
        defaultOutputDir = file('build/resources/main')
    }
}