content.gbs

interactive program{
    INIT -> { PrepararTablero() }
	K_ARROW_LEFT
		-> { MoverHacia(Oeste)}
	K_ARROW_UP
		-> { MoverHacia(Norte)}
	K_ARROW_DOWN
		-> { MoverHacia(Sur)}
	K_ARROW_RIGHT
		-> { MoverHacia(Este)}
	K_SPACE -> { 
		DestaparSiNoHayBandera()
	}
	K_ENTER 
		-> {PonerOSacarBandera()
				ActualizarContadorBanderasYVolver()
				Gano()
	} 
}

procedure PonerLinea(){
		IrAlOrigen()
		Mover(Norte)
		Linea()
		IrAlComienzo()
}

procedure Linea(){
		while( puedeMover(Este)){
		PonerN(2, Rojo)
		Mover(Este)
	}
		PonerN(2, Rojo)
}


procedure ActualizarContadorBanderasYVolver(){
		Marcar()
		ActualizarContadorBanderas()
		IrAMarca()
		SacarMarca()
}


procedure PonerOSacarBandera(){
	if(hayBandera()){
		SacarBandera()
	} else {
		PonerBandera()
	}
}

procedure DestaparVecinas() {
	MarcarTodas()
	DestaparMarcadas()
}

procedure DestaparCelda(){
	if(estaTapada()){
		Sacar(Azul)
	}
}

procedure TaparTablero(){
	IrAlComienzo()
	while(haySiguiente()){
		TaparCelda()
		IrAlSiguiente()
	}
	TaparCelda()
	IrAlComienzo()
}
procedure PonerPista(){
	if (not hayMina()){
		PonerN(cantMinasCercanas(), Verde)
	}
}

procedure PonerTodasLasPistas(){
	while(haySiguiente()){
		PonerPista()
		IrAlSiguiente()
	}
	PonerPista()
	IrAlComienzo()
}

procedure PrepararTablero(){
	TaparTablero()
	PonerTodasLasPistas()
	ActualizarContadores()
}

procedure ActualizarContadores(){
	ActualizarContadorBanderas()
	ActualizarContadorMinas()
	IrAlComienzo()
}

procedure DestaparMarcada() {
	if (hayMarca() && not esPrimeraMarca()){
		SacarMarca()
		DestaparCelda()
	}
}

procedure DestaparMarcadas() {
	while(haySiguiente()){
		DestaparMarcada()
		IrAlSiguiente()
	}
	DestaparMarcada()
	IrAPrimeraMarca()
	SacarTodas(Rojo)
}

procedure Gano(){
	if(totalMinasConBandera() == totalMinas()){
	DestaparTodas()
	}
}

procedure DestaparSiNoHayBandera(){
	if (not hayBandera() && not hayMina()){
		DestaparCelda()
		DestaparVecinas()
	}

	if (hayMina()) {
		DestaparTodas()
	}
}

procedure SacarBanderasIncorrectas(){
	IrAlComienzo()
	while(haySiguiente()){
		if(hayBandera() && not hayMina()){
			SacarBandera()	
		}
		IrAlSiguiente()
	}
}