build.gradle

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'org.sonarqube'
apply plugin: 'com.github.hierynomus.license'
apply plugin: 'maven-publish'
apply plugin: 'com.jfrog.artifactory'
apply plugin: 'signing'
apply plugin: 'maven'
apply plugin: "io.codearte.nexus-staging"
//apply plugin: 'nebula.lint'

sourceCompatibility = 1.8
version = "${version}"
group = 'com.dell.isg.smi'
archivesBaseName = "wsmanlib"
ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

buildscript {
   repositories {
    mavenLocal()
    mavenCentral()
	maven {
		url "${artifactory_contextUrl}/${plugin_repo}"
		url "https://plugins.gradle.org/m2/"
	}
  }
  dependencies {
       classpath "io.spring.gradle:dependency-management-plugin:1.0.2.RELEASE"
       classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.4.15"
       classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.2.1"
       classpath "gradle.plugin.nl.javadude.gradle.plugins:license-gradle-plugin:0.13.1"
       classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.9.0"
       //classpath 'com.netflix.nebula:gradle-lint-plugin:latest.release'
  }
}


//gradleLint {
  //rules  = ['dependency-parentheses','overridden-dependency-version','duplicate-dependency-class', 'all-dependency','unused-dependency']
//}

sonarqube {
    properties {
        property "sonar.projectName", "rackhd :: smi-lib-wsman"
        property "sonar.projectKey", "${group}:wsmanlib"
    }
}

jar {
    manifest {
        attributes 'Implementation-Title': 'wsmanlib jar',
                   'Implementation-Version': version
    }
}

if (JavaVersion.current().isJava8Compatible()) {
    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
    }
}

javadoc {
    options {
         encoding = 'windows-1251'
    }
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

repositories {
	mavenLocal()
	mavenCentral()
	maven { url "${artifactory_contextUrl}/libs-snapshot" }
	maven { url "${artifactory_contextUrl}/libs-release" }
	maven { url "https://repo.maven.apache.org/maven2" }
}

dependencies {
    compile 'com.dell.isg.smi:wsmanclient:1.0.37'
    compile 'com.dell.isg.smi:commons-elm:1.0.76'
    compile 'com.dell.isg.smi:commons-utilities:1.0.32'
    compile 'com.dell.isg.smi:wiseman:1.0.5'
	compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
	compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.5'
	compile group: 'io.swagger', name: 'swagger-annotations', version: '1.5.13'
	compile group: 'commons-io', name: 'commons-io', version: '2.5'
	compile group: 'commons-codec', name: 'commons-codec', version: '1.10'
	compile group: 'org.json', name: 'json', version: '20170516'
	compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.8.9'
	testCompile group: 'junit', name: 'junit', version: '4.12'
}

test {
    systemProperties 'property': 'value'
}

uploadArchives {
	repositories {
		flatDir {
		   dirs 'repos'
		}
		mavenDeployer 
		{
			beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
			
			repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
				authentication(userName: ossrhUsername, password: ossrhPassword)
			}

			snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
				authentication(userName: ossrhUsername, password: ossrhPassword)
			}
	  
			pom.project {
				artifactId = "wsmanlib"
				packaging 'jar'
				url 'https://www.github.com/rackhd/smi-lib-wsman'
				name 'SMI WSMan Library'
				description 'A Jar library with implementation logic for interfacing with Dell Systems using the WS-Management Protocol'
				inceptionYear '2017'
				
				licenses {
					license {
						name 'The Apache Software License, Version 2.0'
						url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
						distribution 'repo'
					}
				}
				
				scm {
					connection 'scm:git:git://www.github.com/rackhd/smi-lib-wsman.git'
					developerConnection 'scm:git:ssh://www.github.com/rackhd/smi-lib-wsman.git'
					url 'http://www.github.com/rackhd/smi-lib-wsman'
				}
				
				developers {
					developer {
						id 'michaelsteven'
						name 'Michael Hepfer'
						email 'michael.hepfer@dell.com'
						organization 'Dell EMC Inc.'
						organizationUrl 'http://codedellemc.com'
						}
				}
				
			}
		}
	}
}

nexusStaging {
    packageGroup = "com.dell.isg.smi"
    //stagingProfileId = "yourStagingProfileId" //when not defined will be got from server using "packageGroup"
}

//gradle closeRepository promoteRepository

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    required { gradle.taskGraph.hasTask("artifactoryPublish") }
    sign configurations.archives
}

publishing {
    publications {
        mavenJava(MavenPublication){
            artifact jar
            artifact sourcesJar {
                classifier "sources"
            }
            artifact javadocJar
        }
    }
}

license {
        header rootProject.file('license-template')
        includes(["**/*.java", "**/*.properties"])
        strictCheck true
        ignoreFailures true
        ext.year = Calendar.getInstance().get(Calendar.YEAR)
    	ext.name = 'DELL Inc.'
}

artifactory {
    contextUrl = "${artifactory_contextUrl}"   //The base Artifactory URL if not overridden by the publisher/resolver
    publish {
        defaults{ publications ("mavenJava")}
        repository {
	    // note: username and password being set by bamboo artifactory plugin
            maven = true
        }
    }
    resolve {
        repository {
            repoKey = 'libs-release'
            maven = true
        }
    }
}