build.gradle

buildscript {
  repositories {
    mavenCentral()
    mavenLocal()
  }
  dependencies {
    classpath 'com.android.tools.build:gradle:0.11.1'
  }
}

repositories {
  maven { url "${System.env.ANDROID_HOME}/extras/android/m2repository" }
}

apply plugin: 'android'

dependencies {
  compile project(':vtm-android')
  compile project(':vtm-themes')
  compile project(':vtm-extras')
}

android {
  compileSdkVersion 19
  buildToolsVersion '19.1'

  sourceSets {
    main {
      manifest.srcFile 'AndroidManifest.xml'
      java.srcDirs = ['src', 'assets']
      resources.srcDirs = ['src', 'assets']
      res.srcDirs = ['res']
      assets.srcDirs = ['assets']
    }

    debug.setRoot('build-types/debug')
    release.setRoot('build-types/release')
  }

  // remove duplicates
  packagingOptions {
    exclude 'META-INF/LICENSE'
    exclude 'META-INF/NOTICE'
  }

  // ignore deprecated
  lintOptions.abortOnError false
}

// Configuring Eclipse
eclipse.classpath {
  plusConfigurations += configurations.compile

  defaultOutputDir = file('bin/classes')

  file {
    withXml {
      def node = it.asNode()
      node.appendNode('classpathentry kind="src" path="src"')
      node.appendNode('classpathentry kind="src" path="gen"')
    }
  }
}
eclipse.project {
  natures = ['com.android.ide.eclipse.adt.AndroidNature',
	     'org.eclipse.jdt.core.javanature']

  buildCommand 'com.android.ide.eclipse.adt.ResourceManagerBuilder'
  buildCommand 'com.android.ide.eclipse.adt.PreCompilerBuilder'
  buildCommand 'com.android.ide.eclipse.adt.ApkBuilder'
}