build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group 'unprotesting.com.github'
version '0.14.4'

ext {
    jettyVersion = '11.0.19'
    lombokVersion = '1.18.30'
    adventureVersion = '4.15.0'
    paperMCVersion = '1.20.4-R0.1-SNAPSHOT'
    bstatsVersion = '3.0.2'
    mapdbVersion = '3.1.0'
    ifVersion = '0.10.13'
    vaultVersion = '1.7.1'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
    maven { url 'https://papermc.io/repo/repository/maven-public/' }
}

dependencies {
    implementation "org.bstats:bstats-bukkit:$bstatsVersion"
    implementation "org.mapdb:mapdb:$mapdbVersion"
    implementation "com.github.stefvanschie.inventoryframework:IF:$ifVersion"
    
    compileOnly "net.kyori:adventure-text-minimessage:$adventureVersion"
    compileOnly "net.kyori:adventure-api:$adventureVersion"
    compileOnly "io.papermc.paper:paper-api:$paperMCVersion"
    compileOnly "com.github.milkbowl:VaultAPI:$vaultVersion"
    compileOnly "org.projectlombok:lombok:$lombokVersion"
    compileOnly "org.eclipse.jetty:jetty-server:$jettyVersion"
    compileOnly "org.eclipse.jetty:jetty-servlet:$jettyVersion"

    annotationProcessor "org.projectlombok:lombok:$lombokVersion"
}

shadowJar {

    relocate "org.bstats", "unprotesting.com.github.bstats"
    relocate "org.mapdb", "unprotesting.com.github.mapdb"
    relocate "com.github.stefvanschie.inventoryframework", "unprotesting.com.github.inventoryframework"

    archiveBaseName.set('Auto-Tune')
    archiveVersion.set(version)
    archiveClassifier.set(null)
    archiveAppendix.set(null)

    minimize()
}

artifacts {
    archives shadowJar
}