build.gradle

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
	id "fabric-loom" version "1.6-SNAPSHOT"
	id "maven-publish"
	id "org.jetbrains.kotlin.jvm" version "1.8.0"
}

version = project.mod_version
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

loom {
	accessWidenerPath = file("src/main/resources/hexical.accesswidener")
}

repositories {
    maven { url = "https://maven.terraformersmc.com/releases" }
    maven { url = "https://maven.shedaniel.me/" }
    maven { url = "https://maven.blamejared.com/" }
    maven { url = "https://maven.jamieswhiteshirt.com/libs-release/" }
    maven { url = "https://mvn.devos.one/snapshots/" }
    maven { url = "https://maven.ladysnake.org/releases" }
	maven { url = "https://api.modrinth.com/maven" }
	maven { url = "https://maven.kosmx.dev/" }
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
	modImplementation "net.fabricmc:fabric-language-kotlin:${project.fabric_kotlin_version}"

	modImplementation "at.petra-k.paucal:paucal-common-$minecraft_version:$paucal_version"
    modImplementation "vazkii.patchouli:Patchouli:$minecraft_version-$patchouli_version-FABRIC"
	modImplementation("at.petra-k.hexcasting:hexcasting-fabric-$minecraft_version:$hexcasting_version") {
		exclude module: "phosphor"
        exclude module: "lithium"
		exclude module: "emi"
	}

	include implementation(annotationProcessor("io.github.llamalad7:mixinextras-fabric:${mixin_extras_version}"))
	include modImplementation("dev.kosmx.player-anim:player-animation-lib-fabric:${player_animator_version}")
}

processResources {
	inputs.property "version", project.version
	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 17
}

tasks.withType(KotlinCompile).configureEach {
	kotlinOptions {
		jvmTarget = 17
	}
}

java {
	withSourcesJar()
	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}