How can I add a template from a function but only for a specific mode?

[smahm006]

Hello I am recreating my emacs setup inspired by this repo where the author uses one config.org to setup his entire emacs.

I want to include template snippets as part of the org file that tempel can pick up from. Now I see from the docs that we can add global/local templates but what I really want is a template only for a specific mode from the function.

My org block looks like this

*** Snippets
Python specific snippets for tempel
#+begin_src emacs-lisp
  (with-eval-after-load 'tempel
	(defvar tempel-python-templates
	  '((imp "import " q))
	  "My python templates.")
	(add-to-list 'tempel-template-sources 'tempel-python-templates))
#+end_src

But the problem is that this 'imp' snippet is available globally. I want it to only be available in python-ts-mode.

In my old setup I used to have a snippets/python.eld file with the following first few lines:

python-ts-mode
(imp "import " q)
(fimp "from " p " import " q)

Is this possible?

[smahm006]

@minad any help please?

[minad]

I think the simplest solution is to only set a variable buffer locally. Then you will automatically get only the templates which fit for this buffer and its mode.

[smahm006]

So I tried to this with with the following code

#+begin_src emacs-lisp
  (with-eval-after-load 'tempel
    (defvar tempel-python-templates
      '((imp "import " q)
        (fimp "from " p " import " q))
      "My python templates.")

    (defun set-python-tempel-templates ()
      "Set Tempel templates for Python mode."
      (setq-local tempel-template-sources '(tempel-python-templates)))

    (add-hook 'python-ts-mode-hook 'set-python-tempel-templates))
#+end_src

But that didin't end up working.

Instead I just added my snippets and had org tangle it into the snippets directory like so:

#+begin_src lisp-data :tangle snippets/python.eld :mkdirp yes
  python-ts-mode
  (imp "import " q)
  (fimp "from " p " import " q)
#+end_src

[minad]

Feel free to keep the discussion open for other interested users.

[soil-less]

Hello,

I too wanted to have my templates inside my org config.
Instead of passing a variable to tempel-template-sources you can pass a function.
I ended up writing a macro to generate those functions so everything can live inside the init.el :

(defmacro tempel-source (name modes templates)
  "Declares a NAME-tempel function as a TEMPLATES source for MODES.

   MODES is a list of modes for which the templates should be available.
   TEMPLATES is a list of tempel templates which will be made available
   for those modes."
  `(progn
  (defun ,(intern (format "%s-tempel" name)) ()
     ,(format "Returns tempel templates if ~major-mode~ member of : %s.
               \nGenerated by tempel-source macro." modes)
     (when (member major-mode ,modes) ,templates))
  (add-to-list 'tempel-template-sources ',(intern (format "%s-tempel" name))))
)

You can then use it like so for multiple modes :

(tempel-source sh '(sh-mode eat-mode) '(
  (if "if [ " (p "condition") " ]; then " r "; fi")
  (ife "if [ " (p "condition") " ]; then " p "; else " p "; fi" r)
  (whilefile "while IFS=\"\" read -r l || [ -n \"$l\" ]; do " p "; done < " r)
  (whilevar "while IFS=\"\" read -r l || [ -n \"$l\" ]; do " p
            "; done < <(printf '%s' \"$" r "\" )")
  (for "for " p " in " p "; do " n r> n"done")
))

Or in your case for a single mode :

(tempel-source python '(python-ts-mode) '(
  (imp "import " q)
  (fimp "from " p " import " q)
))

I also created a template for org-mode to generate those code blocks :D :

(tempel-source org '(org-mode) '(
  (tempel & "#+begin_src elisp :tangle init.el" n
     "(tempel-source " (p "name") " '(" (p "modes") ") '(" n r n
     "))" n
     "#+end_src")
  (src & "#+begin_src " p n r n "#+end_src")
  (init & "#+begin_src elisp :tangle init.el" n r n "#+end_src")
  (tangle & "#+begin_src " p " :tangle " p n r n "#+end_src")
  (link & "[[" p "][" p "]]" q)
  (stat "[/] [%]" q)
  (cb & "- [ ] " q)
))