Provide an outward-facing function for generating tempel abbrev expansions

[Luis-Henriquez-Perez]

tempel-abbrev-mode is too assuming

The solution to #69, namely the introduction of tempel-abbrev-mode and global-tempel-abbrev-mode, is too assuming and overblown and fails to address the issue's core problem. The core problem is that binding an abbreviation to a function that expands a tempel snippet (as I show below) adds an unecessary space after the snippet is expanded. The problem is not a need to automatically generate an abbrev for every template.

(define-abbrev emacs-lisp-mode-abbrev-table "fun" "" (-partial #'tempel-insert 'fun))

recommended solution

What is needed is simply a user-facing function (as shown below) that generates and returns a function that expands into the specified snippet without adding this extra space. This way the user has a convenient way to actually bind an abbrev to a snippet.

(defun tempel-abbrev-def (name)
  "Return a function."
  (let ((template (cdr (assoc name (tempel--templates))))
        (hook (make-symbol (format "tempel--%s-snippet" name))))
    (fset hook (apply-partially #'tempel--abbrev-hook (symbol-name name) template))
    (put hook 'no-self-insert t)
    hook))

real-life example

The provided tempel-abbrev-mode and its counterpart global-tempel-abbrev-mode do not provide a tool for the user to define their own abbrevs. Opinionated in nature, they assume how users want the abbrev snippets defined and do it for them. In contrast, tempel-abbrev-def only facilitates defining abbrev snippets leaving it users to define their own abbrevs the way they want to–choosing the abbrev name, exactly which snippets they want to have an abbrev for, etc.

Below I provide the real-life example where I had a need for this function and tempel-abbrev-mode did not really help at all–other than being a template from which I learned to write tempel-abbrev-def.

(define-abbrev-table 'emacs-lisp-mode-abbrev-table
  (list (list ".fun"   "" (tempel-abbrev-def 'fun))
        (list ".let"   "" (tempel-abbrev-def 'let))
        (list ".p"     "" (tempel-abbrev-def 'pt))
        (list ".var"   "" (tempel-abbrev-def 'var))
        (list ".al"    "" (tempel-abbrev-def 'alias))
        (list ".alias" "" (tempel-abbrev-def 'alias))))
(abbrev-table-put emacs-lisp-mode-abbrev-table :regexp "\\(?:^\\|[	 ]+\\)\\(?1:\\..*\\|.*\\)")

note about laziness

Ideally, tempel should only be loaded (assuming it is not already) when an abbrev that expands to a tempel snippet is expanded. In my example tempel is loaded upon the invocation of tempel-abbrev-def.

[minad]

The core problem is that binding an abbreviation to a function that expands a tempel snippet (as I show below) adds an unecessary space after the snippet is expanded.

Sorry for not answering earlier to your proposal. Does this space problem still exist? Iirc I've fixed this a while ago.

[DivvyCr]

I just stumbled into the same issue. Upon some debugging, I found that the abbrev hook must return non-nil for no-self-insert to take effect:

If hook is a non-nil symbol whose no-self-insert property is non-nil, hook can explicitly control whether to insert the self-inserting input character that triggered the expansion. If hook returns non-nil in this case, that inhibits insertion of the character. By contrast, if hook returns nil, expand-abbrev (or abbrev-insert) also returns nil, as if expansion had not really occurred.
   - Emacs Manual, Defining Abbrevs

Then, my current solution is just to return t from the hook's function:

(define-minor-mode tempel-abbrev-mode
  "Install Tempel templates as abbrevs."
  :group 'tempel
  :global nil
  (setq-local abbrev-minor-mode-table-alist
              (assq-delete-all 'tempel-abbrev-mode abbrev-minor-mode-table-alist))
  (when (eq abbrev-minor-mode-table-alist
            (default-value 'abbrev-minor-mode-table-alist))
    (kill-local-variable 'abbrev-minor-mode-table-alist))
  (when tempel-abbrev-mode
    (let ((table (make-abbrev-table))
          (tempel--ignore-condition t))
      (dolist (template (tempel--templates))
        (let* ((name (symbol-name (car template)))
               (hook (make-symbol name)))
          (fset hook (lambda ()
                       (tempel--delete-word name)
                       (tempel--insert (cdr template) nil)
                       t)) ;; <====== ADD RETURN VALUE HERE ==============================
          (put hook 'no-self-insert t)
          (define-abbrev table name 'Template hook :system t
            :enable-function
            (lambda () (assq (car template) (tempel--templates))))))
      (setq-local abbrev-minor-mode-table-alist
                  (cons `(tempel-abbrev-mode . ,table)
                        abbrev-minor-mode-table-alist)))))

[minad]

Thanks. See a2b7b0e