Transient inifx/suffix class for lisp variable options

[dalanicolai]

While 'investigating' how to make sketch-mode 'compatible' with canvas-mode, I created a
sketch-lisp-variable:choices infix(suffix) class. The intended purpose for this class was to configure/set some buffer local variable. Probably this will not be used in sketch-mode eventually, but it might be useful anyway so I'll share/document it here.
Here is the code (incl. declaration of an infix):

(defclass sketch-lisp-variable:choices (transient-variable)
  ((set-value :initarg :set-value :initform #'set)
   (always-read :initform t)
   (fallback    :initarg :fallback    :initform nil)
   (default     :initarg :default     :initform nil)))

(cl-defmethod transient-init-value ((obj sketch-lisp-variable:choices))
  (oset obj value (symbol-value (oref obj variable))))

(cl-defmethod transient-infix-read ((obj sketch-lisp-variable:choices))
  (let ((choices (oref obj choices))
        (value (oref obj value)))
    (or (cadr (member value choices)) (car choices))))

(cl-defmethod transient-infix-set ((obj sketch-lisp-variable:choices) value)
  (funcall (oref obj set-value)
           (oref obj variable)
           (oset obj value value)))

(cl-defmethod transient-format-description ((obj sketch-lisp-variable:choices))
  (or (oref obj description)
      (symbol-name (oref obj variable))))

;; (cl-defmethod transient-format-value ((obj sketch-lisp-variable:choices))
;;   (propertize (prin1-to-string (oref obj value))
;;               'face 'transient-value))

(cl-defmethod transient-format-value ((obj sketch-lisp-variable:choices))
  (let ((value (symbol-name (oref obj value)))
        (choices (mapcar #'symbol-name (oref obj choices))))
    (concat
     (propertize "[" 'face 'transient-inactive-value)
     (mapconcat (lambda (choice)
                  (propertize choice 'face (if (equal choice value)
                                               (if (member choice choices)
                                                   'transient-value
                                                 'font-lock-warning-face)
                                             'transient-inactive-value)))
                choices
                (propertize "|" 'face 'transient-inactive-value))
     (propertize "]" 'face 'transient-inactive-value))))

(transient-define-infix sketch-object ()
  :description "Option with list"
  :class 'sketch-lisp-variable:choices
  :variable 'sketch-object
  :choices '(line polyline rectangle circle ellipse freehand))

the sketch-mode code contains some more nice examples for how to use transients.

@tarsius It might be handy to remove the reader slot from the transient-lisp-variable because then this code just have inherited most methods from that class (I probably could have set the reader to nil also, but I am not very famliar with EIEIO/CLOS yet).

[tarsius]

To try this out one has to add:

(defvar sketch-object nil)

(transient-define-prefix sketch-prefix ()
  [("x" sketch-object)])

;; (sketch-prefix)

It might be handy to remove the reader slot from the transient-lisp-variable because then this code just have inherited most methods from that class (I probably could have set the reader to nil also, but I am not very famliar with EIEIO/CLOS yet).

That wouldn't change anything and if it did, then yes just setting reader to nil in the derived class would also do the trick.

A lot of this code was lifted from the magit--git-variable:choices class. Because that class deals with git variables it would not be appropriate to derive a class from it that deals with lisp variables (though doing it the other way around may potentially be a reasonable approach).

So yes at this point you have no choice but to copy-paste. In the future I might provide a suitable class or teach an existing class about this style of selecting a value and add a new slot that controls whether it is used or not.

[dalanicolai]

Okay, if reader can be simply set to nil, then the transient-lisp-variable class looks like a good parent class for lisp-variables. Indeed, I copied this code from there and replaced some methods with code, slightly adapted, from the magit--git-variable:choices class. I was just sharing the code as an(other) example for other users.

[tarsius]

#160, #162 and #165 are related, and concern https://github.com/dalanicolai/sketch-mode.