Unable to provision payment method with payment_source_type "ExternalPayment"

[Bart-Kuipers]

Version information

• terraform: 1.9.8
• terraform provider: 0.20.0

Describe the bug

Trying to provision a commercelayer_payment_method resource with attributes.payment_source_type = "ExternalPayment" fails with the following error:

Error: 422 Unprocessable Entity: {"errors":[{"title":"is invalid","detail":"payment_source_type - is invalid","code":"VALIDATION_ERROR","source":{"pointer":"/data/attributes/payment_source_type"},"status":"422","meta":{"error":"invalid"}}]}

To Reproduce

1. Create a single new terraform config with the following content:

terraform {
  required_providers {
    commercelayer = {
      source = "labd/commercelayer"
      version = ">= 0.20.0"
    }
  }
}

variable "commercelayer_client_id" {
  description = "Commerce Layer client ID"
  type        = string
  default     = ""
}

variable "commercelayer_client_secret" {
  description = "Commerce Layer client secret"
  type        = string
  default     = ""
}

variable "commercelayer_auth_endpoint" {
  description = "Commerce Layer authentication endpoint"
  type        = string
  default     = ""
}

variable "commercelayer_api_endpoint" {
  description = "Commerce Layer API endpoint"
  type        = string
  default     = ""
}

provider "commercelayer" {
  client_id     = var.commercelayer_client_id
  client_secret = var.commercelayer_client_secret
  api_endpoint  = var.commercelayer_api_endpoint
  auth_endpoint = var.commercelayer_auth_endpoint
}



resource "commercelayer_manual_gateway" "manual_gateway" {
  attributes {
    name = "Manual gateway"
  }
}

resource "commercelayer_payment_method" "manual_payment_method" {
  attributes {
    payment_source_type = "ExternalPayment"
    currency_code       = "EUR"
    price_amount_cents  = 0
  }

  relationships {
    payment_gateway_id = commercelayer_manual_gateway.manual_gateway.id
  }
}

2. Expose the required env variables
3. Try to apply the config
4. Apply fails with 422 error code

Expected behavior

The payment method should have been created succesfully

[demeyerthom]

Hi @Bart-Kuipers looks like you were connecting the wrong type of payment gateway. It should be as follows:

For external payment methods:

resource "commercelayer_external_gateway" "external_gateway" {
  attributes {
    name = "External gateway"
  }
}

resource "commercelayer_payment_method" "external_payment_method" {
  attributes {
    payment_source_type = "ExternalPayment"
    currency_code       = "EUR"
    price_amount_cents  = 100
  }

  relationships {
    payment_gateway_id = commercelayer_external_gateway.external_gateway.id
  }
}

For manual gateways (e.g. wire transfers or credit cards):

resource "commercelayer_manual_gateway" "manual_gateway" {
  attributes {
    name = "Manual gateway"
  }
}

resource "commercelayer_payment_method" "manual_payment_method" {
  attributes {
    payment_source_type = "WireTransfer"
    currency_code       = "EUR"
    price_amount_cents  = 100
  }

  relationships {
    payment_gateway_id = commercelayer_manual_gateway.manual_gateway.id
  }
}

[Bart-Kuipers]

Hi @demeyerthom,

Thanks for looking into this. You're completely right about using the wrong payment gateway, this was not obvious from the CL documentation. Sorry about that, and thanks for your help!