build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext {
        kotlinVersion = '1.4.32'
        hiltVersion = "2.35"

        ktLintVersion = "0.40.0"
        ktLintWrapperVersion = "10.0.0"
        detektVersion = "1.16.0"
    }

    repositories {
        google()
        jcenter()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:4.1.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "com.google.gms:google-services:4.3.5"
        classpath "com.google.dagger:hilt-android-gradle-plugin:$hiltVersion"
        classpath "com.google.firebase:firebase-crashlytics-gradle:2.5.2"
        classpath "com.vanniktech:gradle-dependency-graph-generator-plugin:0.6.0-SNAPSHOT"
    }
}

plugins {
    id "org.jlleitschuh.gradle.ktlint" version "$ktLintWrapperVersion"
    id "io.gitlab.arturbosch.detekt" version "$detektVersion"
}

apply plugin: "com.vanniktech.dependency.graph.generator"
apply from: rootProject.file("ktlint.gradle")
apply from: rootProject.file("versions.gradle")

allprojects {
    apply from: rootProject.file("detekt.gradle")
    repositories {
        google()
        jcenter()
        maven { url "https://jitpack.io" }
    }
}

wrapper {
    gradleVersion = "6.5"
    distributionType = Wrapper.DistributionType.ALL
}

subprojects { subProject ->
    task allDependencies(type: DependencyReportTask) {}

    project.plugins.withId("com.android.library") {
        // TODO replace with https://issuetracker.google.com/issues/72050365 once released.
        project.android.libraryVariants.all {
            it.generateBuildConfigProvider.configure { it.enabled = false }
        }
    }
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}