community_domains.rq

#+ summary: Get the domains of FAIR Implementation Communities
#+ endpoint: https://query.np.trustyuri.net/repo/type/6a09747868afc83837e38d1bac79362fbcc3e2032cff2f2d244f4e24cbd085c6
#+ method: GET

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix fip: <https://w3id.org/fair/fip/terms/>

select ?domain ?domainlabel (count(distinct ?np) as ?count) where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey ;
      npx:hasNanopubType fip:FAIR-Implementation-Community ;
      np:hasAssertion ?a .
    ?np dct:created ?date . filter(str(?date) > "2022")
    filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
  }
  graph ?a {
    ?community a fip:FAIR-Implementation-Community ;
      rdfs:label ?label ;
      rdfs:comment ?comment ;
      fip:has-research-domain ?domain .
  }
  graph <https://w3id.org/np/RAGL6Knsrg3GPi4Guhkn4NRXLxgGxoHngDXYwcrG3lUMA#assertion> {
    ?domain rdfs:label ?domainlabel .
  }
}
group by ?domain ?domainlabel
order by desc(?count)