File Handling: io.fs

[Whammo]

io.fs may be handled in much the same way.
IORESULT was spun off in open.fs for duplicate code.

require open
: chkin ( file# -- file# ioresult )
dup xr c! $ffc6 sys ioresult ;
: chkout ( file# -- file# ioresult )
dup xr c! $ffc9 sys ioresult ;
: clrchn ( -- ) $ffcc sys ;
: readst ( -- status )
$ffb7 sys ar c@ ;
code chrin ( -- chr )  \ this is as close as we need to get to speed
dex, w stx, 0 lda,# msb sta,x
$ffcf jsr, w ldx, lsb sta,x
;code \ we can still do it in forth
\ : chrin ( -- chr )
\ $ffcf sys ar c@ ;
: ioabort ( file# ioresult -- )
?dup if rvs case
2 of ." file# in use" endof
3 of ." file not open" endof
5 of ." device not present" endof
6 of ." not input file" endof
7 of ." not output file" endof
." io err"
endcase clrchn close cr abort
else drop then ;

Comparing:

require open

\ Use logical file as input device
\ ioresult is 0 on success, kernal
\ error # on failure.
code chkin ( file# -- file# ioresult )
w stx,
lsb lda,x tax, \ x = file#
$ffc6 jsr, \ CHKIN
+branch bcs, \ carry set = error
0 lda,# \ A is only valid on error
:+
w ldx, dex, 
lsb sta,x
0 lda,# msb sta,x
;code

\ Use logical file as output device
\ ioresult is 0 on success, kernal
\ error # on failure.
code chkout ( file# -- file# ioresult )
w stx,
lsb lda,x tax, \ x = file#
$ffc9 jsr, \ CHKOUT
+branch bcs, \ carry set = error
0 lda,# \ A is only valid on error
:+
w ldx, dex,
lsb sta,x
0 lda,# msb sta,x
;code

\ Reset input and output to console 
code clrchn ( -- ) 
txa, pha,
$ffcc jsr,  \ CLRCH
pla, tax,
;code

\ Read status of last IO operation
code readst ( -- status )
dex, 0 lda,# msb sta,x
$ffb7 jsr, \ READST
lsb sta,x
;code

\ Get a byte from input device
code chrin ( -- chr )
dex, w stx, 0 lda,# msb sta,x
$ffcf jsr, \ CHRIN
w ldx, lsb sta,x
;code

\ handle errors returned by open,
\ close, and chkin. If ioresult is 
\ nonzero, close file and abort with
\ an appropriate error message.
: ioabort ( file# ioresult -- )
?dup if rvs case
2 of ." file# in use" endof
3 of ." file not open" endof
5 of ." device not present" endof
6 of ." not input file" endof
7 of ." not output file" endof
." io err" 
endcase clrchn close cr abort
else drop then ;