build.gradle

apply plugin: 'groovy'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'maven-publish'

group = 'com.crygier'
version = '0.6'

jar {
    baseName = 'graphql-jpa'
    version = project.version
}
sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
    maven {
        url  "http://dl.bintray.com/andimarek/graphql-java"
    }
}

configurations {
    provided
    compile.extendsFrom provided
}

dependencies {
    compile 'com.graphql-java:graphql-java:4.2'
    compile 'javax.transaction:javax.transaction-api:1.2'
    provided 'org.hibernate.javax.persistence:hibernate-jpa-2.1-api:1.0.0.Final'

    testCompile "org.springframework.boot:spring-boot-starter:1.5.1.RELEASE"
    testCompile "org.springframework.boot:spring-boot-starter-test:1.5.1.RELEASE"
    testCompile "org.springframework.boot:spring-boot-starter-data-jpa:1.5.1.RELEASE"
    testCompile "org.springframework.boot:spring-boot-starter-web:1.5.1.RELEASE"
    testCompile 'junit:junit:4.11'
    testCompile 'org.spockframework:spock-core:1.0-groovy-2.4'
    testCompile 'org.spockframework:spock-spring:1.0-groovy-2.4'
    testCompile 'org.codehaus.groovy:groovy-all:2.4.4'
    testCompile 'cglib:cglib-nodep:3.1'
    testCompile 'org.objenesis:objenesis:2.1'

    testRuntime "com.h2database:h2:1.4.190"
    //testRuntime 'org.hibernate:hibernate-validator:4.3.0.Final'
}

publishing {
	publications {
		MyPublication(MavenPublication) {
			from components.java
			groupId 'com.crygier'
    		artifactId 'graphql-jpa'
    		version project.version
            artifact sourcesJar
		}
	}
}

model {
    tasks.generatePomFileForMyPublicationPublication {
        destination = file("$buildDir/libs/${project.name}-${version}.pom")
    }

	tasks.assemble {
		dependsOn tasks.generatePomFileForMyPublicationPublication
	}
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives sourcesJar
}

eclipse {
    classpath {
         containers.remove('org.eclipse.jdt.launching.JRE_CONTAINER')
         containers 'org.eclipse.jdt.launching.JRE_CONTAINER/org.eclipse.jdt.internal.debug.ui.launcher.StandardVMType/JavaSE-1.8'
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.3'
}