build.gradle

import org.asciidoctor.gradle.jvm.AsciidoctorTask
import java.text.SimpleDateFormat


plugins {
    id "org.asciidoctor.jvm.base" version "3.3.2"
    id "org.asciidoctor.jvm.convert" version "3.3.2"
    id "org.asciidoctor.jvm.pdf" version "3.3.2"
    id "java"
    id "groovy"
}

repositories {
    mavenCentral()
}

asciidoctorj {
    version = '2.5.3'
}

ext {
    today = new Date()
    versionDate = new SimpleDateFormat("yyyyMMdd").format(today)

    project.version = project.file("./document.version").text
    curriculumFileName = "glossary"
    addSuffixToCurriculum = { suffix ->
        for (extension in ["html", "pdf"]) {
            File source = new File("${buildDir}/${curriculumFileName}.${extension}")
            File target = new File("${buildDir}/${curriculumFileName}${suffix}.${extension}")

            source.renameTo(target)
        }
    }
}


dependencies {
    implementation platform('org.apache.groovy:groovy-bom:4.0.5')
    implementation 'org.apache.groovy:groovy'
    implementation 'org.apache.groovy:groovy-json:3.0.9'
    testImplementation platform("org.spockframework:spock-bom:2.3-groovy-4.0")
    testImplementation "org.spockframework:spock-core"
    testImplementation "org.apache.groovy:groovy-json:4.0.3"


}

task generateTranslationTables(dependsOn: compileGroovy, type: JavaExec) {
    jvmArgs = ['--add-opens', 'java.base/java.lang=ALL-UNNAMED',
               '--add-opens', 'java.base/java.io=ALL-UNNAMED',
               '--add-opens', 'java.base/java.util=ALL-UNNAMED']
    classpath = sourceSets.main.runtimeClasspath
    mainClass = 'Translator'
}



class RenderCurriculumTask extends AsciidoctorTask {
    @Inject
    RenderCurriculumTask(WorkerExecutor we, String curriculumFileName, String versionDate, String language, boolean withRemarks) {
        super(we)

        forkOptions {
            jvmArgs "--add-opens", "java.base/sun.nio.ch=ALL-UNNAMED", "--add-opens", "java.base/java.io=ALL-UNNAMED"
        }


        sourceDir = new File("./docs/")
        baseDir = new File ("./docs/")
        sources {
            include "index.adoc"
            include "${curriculumFileName}.adoc"
        }
        outputDir = new File("./build/")
        outputOptions {
            separateOutputDirs = false
            backends 'pdf', 'html5'
        }

        def fileVersion = project.version.trim() + "-" + language

        attributes = [
                'icons'             : 'font',
                'version-label'     : '',
                'revnumber'         : fileVersion,
                'revdate'           : versionDate,
                'document-version'  : fileVersion + "-" + versionDate,
                'currentDate'       : versionDate,
                'language'          : language,
                'withRemarks'       : withRemarks,
                'curriculumFileName': curriculumFileName,
                'debug_adoc'        : false,
                'pdf-stylesdir'     : '../pdf-theme/themes',
                'pdf-fontsdir'      : '../pdf-theme/fonts',
                'pdf-style'         : 'isaqb',
                'stylesheet'        : '../html-theme/adoc-github.css',
                'stylesheet-dir'    : '../html-theme',
                'front-cover-image': '../cover/cover_' + language.toLowerCase() + '.pdf'
        ]
    }
}

task buildDocs {
    group 'Documentation'
    description 'Grouping task for generating all languages in several formats'
    dependsOn "generateTables", "renderDE", "renderEN"
}

task renderDE(type: RenderCurriculumTask,
        constructorArgs: [curriculumFileName, versionDate, "DE", false]) {
    doLast {
        addSuffixToCurriculum("-de")
    }
    dependsOn "sortTermsAlphabetically"
}

task renderEN(type: RenderCurriculumTask,
        constructorArgs: [curriculumFileName, versionDate, "EN", false]) {
    doLast {
        addSuffixToCurriculum("-en")
    }
    dependsOn "sortTermsAlphabetically"
}

apply from: 'scripts/generateTermTables.gradle'
apply from: 'scripts/sortTermsAlphabetically.gradle'


defaultTasks "buildDocs"