flake.nix

{
  description = "A nix flake that provides a home-manager module to configure spicetify with.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      forSupportedSystems = nixpkgs.lib.genAttrs [
        "x86_64-linux"
        "aarch64-linux"
      ];
      nixpkgsFor = forSupportedSystems (
        system:
        import nixpkgs {
          inherit system;
          config.allowUnfree = true;
        }
      );
    in
    {
      homeManagerModules = {
        spicetify = (import ./module.nix) { isNixOSModule = false; };
        default = self.homeManagerModules.spicetify;
      };
      nixosModules = {
        spicetify = import ./module.nix { isNixOSModule = true; };
        default = self.nixosModules.spicetify;
      };

      # nice aliases
      homeManagerModule = self.homeManagerModules.default;
      nixosModule = self.nixosModules.default;

      templates.default = {
        path = ./template;
        description = "A basic home-manager configuration which installs spicetify with the Dribbblish theme.";
      };

      libs = forSupportedSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
        in
        pkgs.callPackage ./lib { }
      );

      packages = forSupportedSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
        in
        {
          default = self.packages.${system}.spicetify;
          spicetify = pkgs.callPackage ./pkgs { };
        }
      );

      spicePkgs = forSupportedSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
        in
        pkgs.callPackage ./pkgs { }
      );

      checks = forSupportedSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
        in
        {
          default = self.checks.${system}.all-tests;
          all-tests = pkgs.callPackage ./tests { };
          all-themes = pkgs.callPackage ./tests/all-for-theme.nix { };
          all-exts-and-apps = builtins.mapAttrs (_: value: self.checks.${system}.all-for-theme value) (
            builtins.removeAttrs (pkgs.callPackage ./pkgs { }).themes [
              "override"
              "overrideDerivation"
            ]
          );
          minimal-config = pkgs.callPackage ./tests/minimal-config.nix { };
          apps = pkgs.callPackage ./tests/apps.nix { };
        }
      );

      devShells = forSupportedSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
        in
        {
          default = pkgs.mkShell { packages = [ pkgs.nvfetcher ]; };
        }
      );
    };
}