build.gradle

import com.vanniktech.maven.publish.SonatypeHost

plugins {
    id 'checkstyle'
    id 'java'

    // this is a hopefully temporary plugin until maven central can add official gradle support
    id 'com.vanniktech.maven.publish' version '0.29.0'
}

group = 'com.fauna'

compileJava {
    options.encoding = 'UTF-8'
}

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
    withSourcesJar()
}
test {
    useJUnitPlatform {
        excludeTags "perfTests"
    }
}

tasks.register("perfTests", Test) {
    useJUnitPlatform {
        includeTags "perfTests"
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation "com.fasterxml.jackson.core:jackson-core:${jacksonVersion}"
    implementation "com.fasterxml.jackson.core:jackson-databind:${jacksonVersion}"

    testImplementation 'junit:junit:4.13.2'
    testImplementation "org.junit.jupiter:junit-jupiter-api:${junitVersion}"
    testImplementation "org.junit.jupiter:junit-jupiter-params:${junitVersion}"
    testImplementation "org.mockito:mockito-core:${mockitoVersion}"
    testImplementation "org.mockito:mockito-junit-jupiter:${mockitoVersion}"
    testImplementation "com.fasterxml.jackson.datatype:jackson-datatype-jsr310:${jacksonVersion}"
    testImplementation 'org.apache.commons:commons-math3:3.6.1'

    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitVersion}"
}

mavenPublishing {
    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
    signAllPublications()

    coordinates(project.group, project.name, project.version)

    def githubRepo = "github.com/fauna/${project.name}"

    pom {
        name = project.name
        description = 'JVM driver for Fauna'
        url = "https://${githubRepo}"
        licenses {
            license {
                name = 'MPL 2.0'
                url = 'https://www.mozilla.org/en-US/MPL/2.0/'
                distribution = 'repo'
            }
        }
        developers {
            developer {
                name = 'Fauna Engineering'
                id = 'production@fauna.com'
                organization = 'fauna.com'
                organizationUrl = 'https://fauna.com'
            }
        }
        scm {
            url = 'https://${githubRepo}'
            connection = "scm:git:git://${githubRepo}.git"
            developerConnection = "scm:git:git://${githubRepo}.git"
        }

        issueManagement {
            system = 'GitHub'
            url = "https://${githubRepo}/issues"
        }
    }
}

// tasks

tasks.register('printVersion') {
    doLast {
        println project.version
    }
}

tasks.register('writeProps', WriteProperties) {
    destinationFile = file("src/main/resources/version.properties")
    encoding = 'UTF-8'
    property('version', project.version)
    property('name', project.name)
    property('group', project.group)
}

tasks.register('packageJar', Zip) {
    into('lib') {
        from(tasks.jar)
        from(configurations.runtimeClasspath)
    }
    archiveFileName = 'fauna-jvm-package.zip'
}

checkstyle {
    toolVersion = '10.19.0'  // Latest Checkstyle version at the time of writing
    ignoreFailures = false
}

tasks.withType(Checkstyle).configureEach {
    reports {
        xml.required = false
        html.required = true
    }
}

packageJar.dependsOn(compileJava)
processResources.dependsOn(writeProps)
sourcesJar.dependsOn(writeProps)