build.gradle

apply plugin:"groovy"

repositories{
  jcenter()
}

ext{
  drivers = ["firefox","chrome"]
  groovyVersion = "2.4.4"
  spockGroovyVersion = "2.4"
  gebVersion = "0.12.1"
  seleniumVersion = "2.47.1"
}

dependencies{
  testCompile "org.codehaus.groovy:groovy-all:${groovyVersion}"
  testCompile "org.gebish:geb-spock:${gebVersion}"
  testCompile "org.spockframework:spock-core:1.0-groovy-${spockGroovyVersion}"

  drivers.each{ driver ->
    testCompile "org.seleniumhq.selenium:selenium-${driver}-driver:${seleniumVersion}"
  }
}

drivers.each{ driver ->
  task "${driver}Test"(type:Test){
    reports{
      html.destination = reporting.file("$name/tests")
    }

    outputs.upToDateWhen{ false }

    systemProperty "geb.build.reportsDir",reporting.file("$name/geb")
    systemProperty "geb.env", driver
  }
}

chromeTest{
  systemProperty "webdriver.chrome.driver","${System.properties["user.home"]}/.grails/chromedriver"
}

test{
  dependsOn drivers.collect{ driver -> tasks["${driver}Test"] }
  enabled = false
}