From 21bba34af471f907a54a9256d91adcd74c3203cb Mon Sep 17 00:00:00 2001
From: casey langen <casey.langen@gmail.com>
Date: Mon, 28 Oct 2019 04:45:17 +0000
Subject: [PATCH] More robust detection of libatomic

---
 .cmake/CheckAtomic.cmake | 107 +++++++++++++++++++++++++++++++++++++++
 CMakeLists.txt           |  15 ++++--
 2 files changed, 119 insertions(+), 3 deletions(-)
 create mode 100644 .cmake/CheckAtomic.cmake

diff --git a/.cmake/CheckAtomic.cmake b/.cmake/CheckAtomic.cmake
new file mode 100644
index 000000000..0cc051c3c
--- /dev/null
+++ b/.cmake/CheckAtomic.cmake
@@ -0,0 +1,107 @@
+# atomic builtins are required for threading support.
+
+INCLUDE(CheckCXXSourceCompiles)
+INCLUDE(CheckLibraryExists)
+
+# Sometimes linking against libatomic is required for atomic ops, if
+# the platform doesn't support lock-free atomics.
+
+function(check_working_cxx_atomics varname)
+  set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
+  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11")
+  CHECK_CXX_SOURCE_COMPILES("
+#include <atomic>
+std::atomic<int> x;
+int main() {
+  return x;
+}
+" ${varname})
+  set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
+endfunction(check_working_cxx_atomics)
+
+function(check_working_cxx_atomics64 varname)
+  set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
+  set(CMAKE_REQUIRED_FLAGS "-std=c++11 ${CMAKE_REQUIRED_FLAGS}")
+  CHECK_CXX_SOURCE_COMPILES("
+#include <atomic>
+#include <cstdint>
+std::atomic<uint64_t> x (0);
+int main() {
+  uint64_t i = x.load(std::memory_order_relaxed);
+  return 0;
+}
+" ${varname})
+  set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
+endfunction(check_working_cxx_atomics64)
+
+
+# This isn't necessary on MSVC, so avoid command-line switch annoyance
+# by only running on GCC-like hosts.
+if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
+  # First check if atomics work without the library.
+  check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB)
+  # If not, check if the library exists, and atomics work with it.
+  if(NOT HAVE_CXX_ATOMICS_WITHOUT_LIB)
+    check_library_exists(atomic __atomic_fetch_add_4 "" HAVE_LIBATOMIC)
+    if( HAVE_LIBATOMIC )
+      list(APPEND CMAKE_REQUIRED_LIBRARIES "atomic")
+      check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB)
+      if (NOT HAVE_CXX_ATOMICS_WITH_LIB)
+	message(FATAL_ERROR "Host compiler must support std::atomic!")
+      endif()
+    else()
+      message(FATAL_ERROR "Host compiler appears to require libatomic, but cannot find it.")
+    endif()
+  endif()
+endif()
+
+# Check for 64 bit atomic operations.
+if(MSVC)
+  set(HAVE_CXX_ATOMICS64_WITHOUT_LIB True)
+else()
+  check_working_cxx_atomics64(HAVE_CXX_ATOMICS64_WITHOUT_LIB)
+endif()
+
+# If not, check if the library exists, and atomics work with it.
+if(NOT HAVE_CXX_ATOMICS64_WITHOUT_LIB)
+  check_library_exists(atomic __atomic_load_8 "" HAVE_CXX_LIBATOMICS64)
+  if(HAVE_CXX_LIBATOMICS64)
+    list(APPEND CMAKE_REQUIRED_LIBRARIES "atomic")
+    check_working_cxx_atomics64(HAVE_CXX_ATOMICS64_WITH_LIB)
+    if (NOT HAVE_CXX_ATOMICS64_WITH_LIB)
+      message(FATAL_ERROR "Host compiler must support 64-bit std::atomic!")
+    endif()
+  else()
+    message(FATAL_ERROR "Host compiler appears to require libatomic for 64-bit operations, but cannot find it.")
+  endif()
+endif()
+
+## TODO: This define is only used for the legacy atomic operations in
+## llvm's Atomic.h, which should be replaced.  Other code simply
+## assumes C++11 <atomic> works.
+CHECK_CXX_SOURCE_COMPILES("
+#ifdef _MSC_VER
+#include <windows.h>
+#endif
+int main() {
+#ifdef _MSC_VER
+        volatile LONG val = 1;
+        MemoryBarrier();
+        InterlockedCompareExchange(&val, 0, 1);
+        InterlockedIncrement(&val);
+        InterlockedDecrement(&val);
+#else
+        volatile unsigned long val = 1;
+        __sync_synchronize();
+        __sync_val_compare_and_swap(&val, 1, 0);
+        __sync_add_and_fetch(&val, 1);
+        __sync_sub_and_fetch(&val, 1);
+#endif
+        return 0;
+      }
+" LLVM_HAS_ATOMICS)
+
+if( NOT LLVM_HAS_ATOMICS )
+  message(STATUS "Warning: LLVM will be built thread-unsafe because atomic builtins are missing")
+endif()
+
diff --git a/CMakeLists.txt b/CMakeLists.txt
index cb1dd09a5..b8fc362ae 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -11,7 +11,9 @@ set (musikcube_VERSION_MINOR 70)
 set (musikcube_VERSION_PATCH 0)
 set (musikcube_VERSION "${musikcube_VERSION_MAJOR}.${musikcube_VERSION_MINOR}.${musikcube_VERSION_PATCH}")
 
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR}/.cmake)
 include(CMakeToolsHelpers OPTIONAL)
+include(CheckAtomic)
 
 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++14 -Wno-unused-result -Wno-deprecated-declarations")
 
@@ -48,12 +50,19 @@ set(COMMON_LINK_LIBS ${BOOST_LINK_LIBS} curl pthread crypto)
 
 if (CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
   set (musikcube_LINK_LIBS ${COMMON_LINK_LIBS})
-elseif(CMAKE_SYSTEM_NAME MATCHES "Darwin")
-  set (musikcube_LINK_LIBS ${COMMON_LINK_LIBS} dl)
 else()
-  set (musikcube_LINK_LIBS ${COMMON_LINK_LIBS} dl atomic)
+  set (musikcube_LINK_LIBS ${COMMON_LINK_LIBS} dl)
+endif()
+
+if(NOT HAVE_CXX_ATOMICS_WITHOUT_LIB)
+  if(NOT HAVE_CXX_ATOMICS64_WITHOUT_LIB)
+    message(STATUS "[build] libatomic required, adding to library list")
+    set (musikcube_LINK_LIBS ${musikcube_LINK_LIBS} atomic)
+  endif()
 endif()
 
+message(STATUS "[build] link libraries are: ${musikcube_LINK_LIBS}")
+
 include_directories (
   "${musikcube_SOURCE_DIR}/src"
   "${musikcube_SOURCE_DIR}/src/core"