build.gradle

plugins {
    id "com.github.ethankhall.semantic-versioning" version "1.1.0"
    id "com.github.hierynomus.license" version "0.12.1"
    id "net.saliman.properties" version "1.4.6"
}

project.version.with {
    major = textIoSwingHandlerVersionMajor as int
    minor= textIoSwingHandlerVersionMinor as int
    patch = textIoSwingHandlerVersionPatch as int
    if (project.hasProperty('textIoSwingHandlerVersionLabel')) {
        preRelease = textIoSwingHandlerVersionLabel
    }
    releaseBuild = Boolean.valueOf(textIoSwingHandlerReleaseBuild)
}
ext.textIoSwingHandlerVersion = project.version as String
ext.textIoSwingHandlerTag = Boolean.valueOf(textIoSwingHandlerReleaseBuild) ? "v$ext.textIoSwingHandlerVersion" : 'master'

repositories {
    jcenter()
    mavenCentral()
}

apply plugin: 'application'
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'com.github.hierynomus.license'

sourceCompatibility = 1.8
group = 'org.beryx'
version = textIoSwingHandlerVersion

def defaultEncoding = 'UTF-8'
[compileJava, compileTestJava]*.options*.encoding = defaultEncoding

license {
    header rootProject.file("license-header.txt")
    skipExistingHeaders true
    ignoreFailures false
    excludes (['**/*.properties'])
}

dependencies {
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    compile 'org.beryx:text-io:3.3.0'
    compile 'org.apache.commons:commons-lang3:3.8.1'
    runtime ('ch.qos.logback:logback-classic:1.2.3')
}

jar {
    manifest {
        attributes 'Implementation-Title': "text-io-swing-handler",
                'Main-Class': 'org.beryx.swing.handler.Demo',
                'Implementation-Version': textIoSwingHandlerVersion
    }
}
mainClassName = 'org.beryx.swing.handler.Demo'