build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

apply from: 'properties.gradle'

version '5.5.0'

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    group 'org.citydb'
    version parent.version

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(11)
        }
        compileJava {
            options.encoding = 'UTF-8'
        }
        withJavadocJar()
        withSourcesJar()
    }

    repositories {
        maven {
            url 'https://repo.osgeo.org/repository/release'
        }
        maven {
            url 'https://oss.sonatype.org/content/repositories/snapshots/'
        }
        maven {
            url 'https://3dcitydb.org/maven'
        }
        mavenCentral()
    }

    task processLicense(type: Copy) {
        from("$rootDir/resources/license/LICENSE.txt") {
            filteringCharset = 'UTF-8'
            filter(ReplaceTokens, tokens: [
                    name: project.impexpName
            ])
        }
        into "$projectDir/build/tmp/license"
    }

    javadoc {
        include 'org/citydb/**'
        options {
            overview "$projectDir/build/tmp/javadoc/overview.html"
            header "${project.name} ${project.version}"
            bottom """
                <a href="${impexpIssueTrackerUrl}">Report a bug or suggest an enhancement</a><br>
                ${project.name} is open source and licensed under the <a target="_blank" href="http://www.apache.org/licenses/LICENSE-2.0">Apache License, Version 2.0</a>.<br>
                Official website and more information at: <a target="_blank" href="${project.citydbWebsiteUrl}">${project.citydbWebsiteUrl}</a><br>
                Copyright &copy; ${project.vendorCopyright}<br>
                ${project.vendorName}<br>
                ${project.vendorOrganisation}, ${project.vendorCountry}<br>
                <a target="_blank" href="${project.vendorWebsiteUrl}">${project.vendorWebsiteUrl}</a>
                """.replaceAll("[\r|\n]+", "")
            addStringOption('doctitle', project.name + ' - ' + project.version)
            addStringOption('Xdoclint:none', '-quiet')
        }

        if (JavaVersion.current().isJava9Compatible()) {
            options.addBooleanOption('html5', true)
        }

        doFirst {
            copy {
                from("$rootDir/resources/javadoc/overview.html") {
                    filteringCharset = 'UTF-8'
                    filter(ReplaceTokens, tokens: [
                            name: project.name,
                            version: project.version,
                            impexpName: project.impexpName,
                    ])
                }
                into "$projectDir/build/tmp/javadoc"
            }
        }
    }

    jar {
        manifest {
            attributes('Implementation-Title': project.impexpName,
                    'Implementation-Version': project.version,
                    'Implementation-Vendor': project.vendorName + ', ' + project.vendorOrganisation
            )
        }
        into('META-INF') {
            from "$rootDir/resources/license/APACHE-2.0.txt"
            from processLicense
        }
    }

    publishing {
        publications {
            maven(MavenPublication) {
                from components.java
            }
        }
        repositories {
            maven {
                url project.hasProperty('gitLab_maven_url') ? project.property('gitLab_maven_url') : System.getenv('GITLAB_MAVEN_URL')
                name 'gitlab-maven'
                credentials(HttpHeaderCredentials) {
                    name = 'Private-Token'
                    value = project.hasProperty('gitLab_private_token') ? project.property('gitLab_private_token') : System.getenv('GITLAB_PRIVATE_TOKEN')
                }
                authentication {
                    header(HttpHeaderAuthentication)
                }
            }
        }
    }
}