build.gradle

buildscript {
    repositories {
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.0.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.6'
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.0.0"
    }
}

subprojects {
    description = 'Swagger2Markup extensions.'
    version = '1.3.3'
    group = 'io.github.swagger2markup'

    apply plugin: 'java'
    apply from: "$rootDir/gradle/coverage.gradle"

    ext {
        junit = "4.11"
        swagger2markup = "1.3.3"
    }

    tasks.withType(JavaCompile) {
        sourceCompatibility = "1.8"
        targetCompatibility = "1.8"
        options.deprecation = true
        options.encoding = 'UTF-8'
        options.compilerArgs << "-Xlint:unchecked"
    }

    repositories {
        //mavenLocal()
        jcenter()
        mavenCentral()
        maven {
            url "https://oss.jfrog.org/artifactory/oss-snapshot-local"
        }
    }

    dependencies {
        compile "io.github.swagger2markup:swagger2markup:${swagger2markup}"
        testCompile "junit:junit:${junit}"
        testCompile 'ch.qos.logback:logback-classic:1.1.2'
        testCompile 'org.assertj:assertj-core:2.2.0'
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.12'
}