build.gradle

plugins {
    id 'java'
    id "org.sonarqube" version "2.8"
    id "eu.davidea.grabver" version "1.0.0"
    id 'org.spongepowered.plugin' version '0.8.1'
    id 'maven-publish'
}

compileJava.options.encoding = 'UTF-8'

sponge {
    plugin {
        id = 'storyteller'
    }
}


apply plugin: 'org.spongepowered.plugin'

sourceCompatibility = 1.8
targetCompatibility = 1.8

group = 'com.onaple'
version = "1.4.1" // Change plugin version here

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
    maven { url 'https://oss.sonatype.org/service/local/staging/deploy/maven2' }
    maven {
            name = 'sponge'
            url = 'https://repo.spongepowered.org/maven'
    }
}

[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

dependencies {
    compileOnly 'org.spongepowered:spongeapi:7.2.0'
    testCompile "junit:junit:4.11"
    compile 'com.github.Sponge-RPG-dev:ConfigurateButWithBlackjackAndHookers:39d5fc8afd'
    implementation 'com.github.OnapleRPG:Itemizer:1.1.+'
    implementation 'com.github.OnapleRPG:EpicBoundaries:V0.2.0'
}

sonarqube {
    properties {
        property "sonar.projectName", "Storyteller"
        property "sonar.organization", "ylinor-github"
        property "sonar.host.url", "https://sonarcloud.io/"
    }
}
jar {
    from {
        configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
    }
}
publishing {
    repositories {
        maven {
            name = "GitHubPackages"
            url = "https://maven.pkg.github.com/OnapleRPG/Storyteller"
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
    publications {
        MyPublication(MavenPublication) {
            from components.java
            groupId 'com.onaple'
            artifactId 'storyteller'
            pom {
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'HBeau'
                        name = 'Hugo Beaucamps'
                    }
                    developer {
                        id = 'zessirb'
                        name = 'Olivier Brissez'
                    }
                }
            }
        }
    }
}

allprojects {
    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
        }
    }
}