build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
	String urlStr = "http://mvn.mob.com/android"
	if (rootProject.hasProperty("mavenUrl")) {
		urlStr = rootProject.ext.mavenUrl
	}
	println "mavenUrl: ${urlStr}"
	ext {
		mavenUrl = urlStr
	}

	repositories {
		jcenter()
        google()
		maven {
			url mavenUrl
		}
	}
    dependencies {
        classpath 'com.android.tools.build:gradle:3.5.2'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
        // 注册MobSDK
        classpath 'com.mob.sdk:MobSDK:+'
    }
    configurations.all {
        resolutionStrategy.cacheDynamicVersionsFor 0, 'seconds'
    }
}

allprojects {
	repositories {
		jcenter()
        google()
        maven {
            url mavenUrl
        }
	}
    configurations.all {
        resolutionStrategy.cacheDynamicVersionsFor 0, 'seconds'
    }
}

ext {
    buildTool = findBuildTools()
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

String findBuildTools() {
	def sdkDir = System.env.ANDROID_HOME;
	if(sdkDir == null) {
		def localProperties = new File(project.rootDir, "local.properties")
    	if (localProperties.exists()) {
        	Properties properties = new Properties()
        	localProperties.withInputStream {
            	instr->properties.load(instr)
        	}
        	sdkDir = properties.getProperty('sdk.dir')
		}
	}
    if (sdkDir != null) {
        def buildTools = new File(sdkDir, "build-tools")
        if (buildTools.exists()) {
            def tools = buildTools.list()
            if (tools != null) {
                Arrays.sort(tools)
                return tools[tools.length - 1]
            }
        }
    }
    return null
}