build.gradle

plugins {
    id 'eclipse'
    id 'idea'
    id 'java'
    id 'maven-publish'
    id 'org.cadixdev.licenser' version '0.6.1'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
    id 'net.minecraftforge.gradleutils' version '1.+'
}

repositories {
    mavenCentral()
    maven {
        name 'mojang'
        url 'https://libraries.minecraft.net/'
    }
}

ext {
    GIT_INFO = gradleutils.gitInfo
}

group = 'net.minecraftforge'
archivesBaseName = 'legacydev'
version = gradleutils.getTagOffsetVersion()
targetCompatibility = sourceCompatibility = compileJava.sourceCompatibility = compileJava.targetCompatibility = '1.8'

license {
  header project.file('LICENSE-header.txt')
  include 'net/minecraftforge/legacydev/**/*.java'
  newLine false
}

ext {
    MANIFEST = manifest{
        attributes([
            'Specification-Title': 'accesstransformers',
            'Specification-Vendor': 'Forge Development LLC',
            'Specification-Version': GIT_INFO.tag,
            'Implementation-Title': project.name,
            'Implementation-Vendor': 'Forge Development LLC',
        ] as LinkedHashMap, 'net/minecraftforge/legacydev/')
    }
}

configurations {
    shade
}

dependencies {
    shade 'net.sf.jopt-simple:jopt-simple:5.0.4'
    implementation('net.minecraft:launchwrapper:1.12') {
        exclude group: 'org.ow2.asm'
    }
    implementation 'com.google.guava:guava:21.0'
}

compileJava {
    options.encoding = 'UTF-8'
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier = 'sources'
    from sourceSets.main.allSource
    manifest.from(MANIFEST)
}

shadowJar {
    classifier 'fatjar'
    configurations = [ project.configurations.shade ]
    manifest.from(MANIFEST)
}

artifacts {
    archives shadowJar
    archives sourcesJar
}

jar {
    manifest.from(MANIFEST)
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact sourcesJar
            artifact shadowJar
            artifact jar
            pom {
                name = project.archivesBaseName
                packaging = 'jar'
                description = 'Minecraft Forge Legacy Dev'
                url = 'https://github.com/MinecraftForge/LegacyDev'

                scm {
                    url = 'https://github.com/MinecraftForge/LegacyDev'
                    connection = 'scm:git:git://github.com/MinecraftForge/LegacyDev.git'
                    developerConnection = 'scm:git:git@github.com:MinecraftForge/LegacyDev.git'
                }

                issueManagement {
                    system = 'github'
                    url = 'https://github.com/MinecraftForge/LegacyDev/issues'
                }

                developers {
                    developer {
                        id = 'LexManos'
                        name = 'Lex Manos'
                    }
                }
            }
        }
    }
    repositories {
        maven {
            if (System.env.MAVEN_USER) {
                url "https://maven.minecraftforge.net/releases/"
                authentication {
                    basic(BasicAuthentication)
                }
                credentials {
                    username = System.env.MAVEN_USER ?: 'not'
                    password = System.env.MAVEN_PASSWORD ?: 'set'
                }
            } else {
                url 'file://' + rootProject.file('repo').getAbsolutePath()
            }
        }
    }
}