build.gradle

def minecraft_version="1.12.2"
def jei_version="4.8.5.147"
def version_minetweaker="4.0.8.277"
def version_rf="1.12-2.1.0.6"
def version_mjrlegendslib="1.12.2-1.2.1"
def version_planetprogression="1.12.2-0.3.8"
def version_galacticraft="1.12.2-4.0.2.255"
def version_mekanism="1.12.2-9.4.13.349"
def version_ic2="2.8.99-ex112"
def version_numina="1.12.2-1.0.38"
def version_modularpowersuits="1.12.2-1.0.46"

// For those who want the bleeding edge
buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
		maven {
			url 'https://plugins.gradle.org/m2/'
		}
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
		classpath "gradle.plugin.com.matthewprenger:CurseGradle:1.1.0"
    }
}

repositories {
    maven {
        url = 'https://maven.galacticraft.net/repository/maven-common/'
    }
    maven {
        name 'DVS1 Maven FS'
        url 'https://dvs1.progwml6.com/files/maven'
    }
    maven {
        name 'Blame Jared Maven'
        url 'https://maven.blamejared.com'
    }
    maven {
        name 'Redstone Flux'
        url = "https://maven.covers1624.net"
    }
    maven {
        name 'IC2'
        url = "https://maven.ic2.player.to"
    }
    maven {
        name 'MJRLegends'
        url = "https://maven.mjrlegends.com/"
    }
    maven {
        name 'galacticraft'
        url = 'https://maven.galacticraft.net/repository/legacy'
    }
    maven {
        name 'CurseMaven'
        url 'https://www.cursemaven.com'
    }
}

apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'com.matthewprenger.cursegradle'

version = "1.12.2-0.8.0"
group= "com.mjr.extraplanets" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "ExtraPlanets"

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

minecraft {
    version = "1.12.2-14.23.5.2847"
    runDir = "run"
    mappings = "snapshot_20171003"
    makeObfSourceJar = true // an Srg named sources jar is made by default. uncomment this to disable.
}

dependencies {
	deobfCompile "CraftTweaker2:CraftTweaker2-MC1120-Main:1.12-${version_minetweaker}"
	compile "mezz.jei:jei_${minecraft_version}:${jei_version}:api"
	deobfCompile "cofh:RedstoneFlux:${version_rf}:deobf"
	compile "net.industrial-craft:industrialcraft-2:${version_ic2}:api"
	deobfCompile "com.mjr.mjrlegendslib:MJRLegendsLib:${version_mjrlegendslib}:dev"
	compile "com.mjr.planetprogression:PlanetProgression:${version_planetprogression}:api"
	deobfCompile "curse.maven:mekanism-api-268560:2572882"
	deobfCompile "curse.maven:numina-235440:4629835"
	deobfCompile "curse.maven:modularpowersuits-235442:4623218"
	runtime "mezz.jei:jei_${minecraft_version}:${jei_version}"
	compile files (
		"Galacticraft-API-${version_galacticraft}.jar",
		"GalacticraftCore-Dev-${version_galacticraft}.jar",
		"Galacticraft-Planets-Dev-${version_galacticraft}.jar",
		"MicdoodleCore-Dev-${version_galacticraft}.jar"
	)
}

processResources
{
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
		expand 'version':project.version, 'mcversion':project.minecraft.version
    }
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'dev'
	//manifest {
    //    attributes.put("FMLAT", "extraplanets_at.cfg")
    //    attributes.put("FMLCorePluginContainsFMLMod", "true")
    //}
}

task apiJar(type: Jar) {
    from(sourceSets.main.output) {
        include "com/mjr/extraplanets/api/**"
    }
	from(sourceSets.main.java) {
        include "com/mjr/extraplanets/api/**"
    }
    classifier = 'api'
}

task signJar(type: SignJar, dependsOn: reobfJar) {
    onlyIf {
        project.hasProperty('keyStore')
    }
    keyStore = project.findProperty('keyStore')
    alias = project.findProperty('keyStoreAlias')
    storePass = project.findProperty('keyStorePass')
    keyPass = project.findProperty('keyStoreKeyPass')
    inputFile = jar.archivePath
    outputFile = jar.archivePath
}

artifacts {
    archives apiJar, deobfJar
}

task ("uploadMaven"){
	apply plugin: 'maven'
	uploadArchives {
		repositories {
			mavenDeployer {
				if (project.hasProperty("local_maven")) {
					repository(url: "file://${local_maven}")
				}
			}
		}
	}
}

curseforge {
    if (project.hasProperty('curseforge_key')){
		apiKey = project.findProperty("curseforge_key")
		project {
			id = "241291"
			releaseType = "release"
			addGameVersion "${minecraft_version}"
			mainArtifact(jar) {
				relations {
					requiredLibrary 'mjrlegendslib'
				}
			}
			addArtifact(apiJar)
			addArtifact(deobfJar)
		}
	}
}

build.dependsOn signJar
tasks.build.dependsOn signJar
tasks.curseforge.dependsOn build