build.gradle

plugins {
	id 'maven-publish'
	id 'fabric-loom' version '1.6-SNAPSHOT'
	id 'ploceus' version '1.6-SNAPSHOT'
	id "com.github.johnrengelman.shadow" version "8.1.0" // for mixin extra shadowJar
}

base {
	archivesName = project.archives_base_name
}
version = "${project.version}+mc${project.minecraft_version}"
group = project.maven_group

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
	maven { url 'https://jitpack.io' }
}

configurations {
	implementation.extendsFrom shadow
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings ploceus.featherMappings(project.feather_build)

	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
//	include(implementation(annotationProcessor("io.github.llamalad7:mixinextras-fabric:${project.mixin_extra_version}")))
	// shadow jar to include mixin extra for older fabric loader version
	include(shadow(annotationProcessor("io.github.llamalad7:mixinextras-common:${project.mixin_extra_version}")))

	// carpet core
	modImplementation "com.github.CrazyHPi:ornithe-carpet:${carpet_core_version}"

	// osl if you want
	// ploceus.addCommonLibraries()
	// ploceus.dependOsl(project.osl_version)
}

shadowJar {
	configurations = [project.configurations.shadow]
	relocate("com.llamalad7.mixinextras", "carpetextra.libs.mixinextras")
	mergeServiceFiles() // Very important!
}

processResources {
	inputs.property 'version', version

	filesMatching('fabric.mod.json') {
		expand 'version': version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = 'UTF-8'
	it.options.release = 8
}

java {
	// Still required by IDEs such as Eclipse and Visual Studio Code
	sourceCompatibility = JavaVersion.VERSION_1_8
	targetCompatibility = JavaVersion.VERSION_1_8

	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	// If this mod is going to be a library, then it should also generate Javadocs in order to aid with development.
	// Uncomment this line to generate them.
	// withJavadocJar()
}

// If you plan to use a different file for the license, don't forget to change the file name here!
jar {
	from('LICENSE') {
		rename { "${it}_${base.archivesName.get()}" }
	}
}

// Configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}