build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.3.0' apply false // 루트 프로젝트에서 즉시 적용되지 않도록 설정
    id 'io.spring.dependency-management' version '1.1.5' apply false // 루트 프로젝트에서 즉시 적용되지 않도록 설정
}

/**
 * 전체 프로젝트에 적용되는 설정
 * 적용대상 : 루트 프로젝트와 모든 서브 프로젝트
 * 목적 : 모든 프로젝트에 공통으로 적용되는 설정을 정의
 */
allprojects {
    group = 'org.haedal'
    version = '0.0.1-SNAPSHOT'

    repositories {
        mavenCentral()
    }
}

/**
 * 서브 프로젝트에 적용되는 설정
 * 적용대상 : 모든 서브 프로젝트 (루트 프로젝트 제외)
 * 목적 : 서브 프로젝트에 공통으로 적용되는 설정을 정의
 */
subprojects {
    apply plugin: 'java'
    apply plugin: 'io.spring.dependency-management' // 서브 프로젝트 블록안에서 적용
    apply plugin: 'org.springframework.boot' // 서브 프로젝트 블록안에서 적용

    sourceCompatibility = '17'

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    /**
     * Spring Boot Plugin 설정
     * bootJar 빌드를 하지 않음
     */
    tasks.named('bootJar') {
        enabled = false
    }

    /**
     * jar 빌드를 함
     * jar은 실행 가능한 jar 파일을 생성
     */
    tasks.named('jar') {
        enabled = true
    }

    tasks.named('test') {
        useJUnitPlatform()
    }

    /**
     * 모든 서브 프로젝트에서 공통으로 사용하는 의존성 설정
     */
    dependencies {
        // Lombok
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
    }


}