build.gradle

plugins {
    id "fabric-loom" version "0.2.6-SNAPSHOT"
    id "maven-publish"
    id "signing"
}

group = "com.jamieswhiteshirt"
archivesBaseName = "developer-mode"
version = "1.0.15"

sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8

repositories {
    maven {
        url "https://oss.sonatype.org/content/repositories/snapshots"
    }
}

minecraft {
}

dependencies {
    minecraft "com.mojang:minecraft:1.15"
    mappings "net.fabricmc:yarn:1.15+build.2:v2"
    modImplementation "net.fabricmc:fabric-loader:0.7.2+build.174"
    modImplementation "net.fabricmc.fabric-api:fabric-resource-loader-v0:0.1.+"

    compileOnly "com.google.code.findbugs:jsr305:3.0.2"
}

task sourcesJar(type: Jar, dependsOn: classes) {
	archiveClassifier = 'sources'
	from sourceSets.main.allSource
}

project.ext.isReleaseVersion = !version.endsWith("-SNAPSHOT")

publishing {
    publications {
        mavenJava(MavenPublication) {
            afterEvaluate {
                artifact remapJar
                artifact(sourcesJar.archiveFile) {
                    classifier = "sources"
                    builtBy remapSourcesJar
                }
            }
        }
    }
    repositories {
        maven {
            def releasesRepoUrl = 'https://maven.jamieswhiteshirt.com/libs-release/'
            def snapshotsRepoUrl = 'https://maven.jamieswhiteshirt.com/libs-snapshot/'
            url = isReleaseVersion ? releasesRepoUrl : snapshotsRepoUrl

            credentials {
                username project.properties.mavenUser
                password project.properties.mavenPassword
            }
        }
    }
}

signing {
    required = isReleaseVersion
    sign publishing.publications.mavenJava
}