build.gradle

plugins {
    id 'java'
    id 'application'
    id 'maven-publish'
    id "com.github.johnrengelman.shadow" version "7.1.2"
}

project.version = '2.1.0-dev2'
group = "java.minicraft"
archivesBaseName = "minicraft-plus"

def ENV = System.getenv()


sourceCompatibility = 8
mainClassName = 'minicraft.core.Game'
[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

repositories {
    mavenCentral()

    maven {
        url "https://www.jabylon.org/maven/"
    }
}

dependencies {
    implementation 'org.jetbrains:annotations:23.0.0'
    implementation 'org.xbill:dns:2.0.8'
    implementation 'org.json:json:20211205'
    implementation 'com.mashape.unirest:unirest-java:1.4.9'
    implementation 'org.tinylog:tinylog-api:2.4.1'
    implementation 'org.tinylog:tinylog-impl:2.4.1'
}

java {
    withSourcesJar()
}

shadowJar {
    archivesBaseName = 'minicraft_plus'
    archiveClassifier.set('')

    manifest {
        attributes(
                'Main-Class': mainClassName,
                'Implementation-Title': project.name,
                'Implementation-Version': project.version,
                'SplashScreen-Image': "Minicraft_Splash_Screen_3.png")
    }
}
publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact(shadowJar)
            artifact(sourcesJar)
            pom.withXml {
                subprojects.each {
                    if (it.name != project.testmods_project) {
                        depNode.appendNode("groupId", it.group)
                        depNode.appendNode("artifactId", it.name)
                        depNode.appendNode("version", it.version)
                        depNode.appendNode("scope", "compile")
                    }
                }
            }
        }
    }
    repositories {
        if (ENV.MAVEN_PUBLISH_TOKEN) {
            maven {
                url 'https://repo.repsy.io/mvn/minicraftplus/minicraft'
                credentials {
                    username ENV.MAVEN_PUBLISH_USERNAME
                    password ENV.MAVEN_PUBLISH_TOKEN
                }
                authentication {
                    basic(BasicAuthentication)
                }
            }
        }
    }
}