build.gradle

//NOTE: This file is customized only for this project!

plugins {
	id 'com.github.johnrengelman.shadow' version '5.1.0'
	id 'java'
	id 'fabric-loom' version '0.2.5-SNAPSHOT'
	id 'maven-publish'
}

apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'java'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

minecraft {
}
repositories {
	mavenCentral()
	maven { url 'https://jitpack.io' }
	maven { url 'http://server.bbkr.space:8081/artifactory/libs-release' }
}

shadowJar {
	classifier = "shadow"
	configurations = [project.configurations.shadow]
}

dependencies {
	//to change the versions see the gradle.properties file
	compile group: 'org.jetbrains', name: 'annotations', version: "${project.jetbrains_annotations}"

	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}"
	modCompile "net.fabricmc:fabric-loader:${project.loader_version}"

	modImplementation "com.github.indi-code:TinyConfig:${project.tiny_config_version}"
	modImplementation "com.github.indi-code:Thimble-Permissions:${project.thimble_permissions_version}"

	include "com.github.indi-code:TinyConfig:${project.tiny_config_version}"
	include "com.github.indi-code:Thimble-Permissions:${project.thimble_permissions_version}"

	shadow group: 'com.electronwill.night-config', name: 'yaml', version: "${project.night_config_yaml_version}"
	shadow group: 'mysql', name: 'mysql-connector-java', version: "${project.jdbc_sql_version}"

}

tasks.jar.archiveClassifier = "compile"

//remapJar {
//	classifier = "snapshot"
//}

task remapJar(type: net.fabricmc.loom.task.RemapJarTask, overwrite: true) {
	from zipTree(shadowJar.archiveFile) dependsOn shadowJar
}


processResources {
	inputs.property "version", project.version

	from(sourceSets.main.resources.srcDirs) {
		include "fabric.mod.json", "mod.properties"
		expand "version": project.version, "fabric_loader_version": project.loader_version,
				"fabric_yarn_mappings": project.yarn_mappings, "mc_version": project.minecraft_version
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude "fabric.mod.json", "mod.properties"
	}
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
	options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
	classifier = "sources"
	from sourceSets.main.allSource
}

jar {
	from "LICENSE"
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// select the repositories you want to publish to
	repositories {
		// uncomment to publish to the local maven
		// mavenLocal()
	}
}