build.gradle

buildscript {
    ext.kotlinVersion = '1.4.32'
    repositories {
        jcenter()
        mavenCentral()
        maven {
            name = 'gradle-plugins'
            url = 'https://plugins.gradle.org/m2'
        }
        maven {
            name = "forge"
            url = "https://files.minecraftforge.net/maven"
        }
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
    }
    dependencies {
        classpath('net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT') {
            // The gradle Kotlin plugin depends on Intellij's custom fork
            // of GNU Trove, which it doesn't relocate.
            // Therefore, we need to remove any other version of Trove
            // from the classpath, to ensure that 'gnu.trove.*' always
            // resolves to Intellij's version of Trove at runtime
            // See https://youtrack.jetbrains.com/issue/IDEA-211616
            exclude group: 'trove', module: 'trove'
            exclude group: 'net.sf.trove4j', module: 'trove4j'
        }
        classpath 'gradle.plugin.org.spongepowered:spongegradle:0.8.1'
        classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    }
}

apply from: project.file("gradle/versions.gradle")

ext.foxCoreCommon = findProject('FoxCore-Common')
if (ext.foxCoreCommon == null) ext.foxCoreCommon = findProject(':FoxCore-Common')

apply plugin: 'kotlin'
apply plugin: 'org.spongepowered.plugin'
apply plugin: 'net.minecraftforge.gradle.forge'

group = 'net.foxdenstudio.sponge'
version = 'api7-SNAPSHOT'

apply from: ext.foxCoreCommon.file("gradle/config.gradle")
apply from: ext.foxCoreCommon.file("gradle/fox.gradle")
apply from: ext.foxCoreCommon.file("gradle/publish.gradle")
apply from: project.file("gradle/minecraft.gradle")
apply from: project.file("gradle/foxcore.gradle")

dependencies {
    compile project.ext.foxCoreCommon
    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion"
    compile 'org.spongepowered:mixin:0.8'
    compileOnly "org.spongepowered:spongeapi:$spongeVersion"
    //compile 'com.flowpowered:flow-math:1.0.3'
    //compile 'org.mapdb:mapdb:3.0.5'
    //compile 'net.minecrell.mcstats:statslite-sponge:0.2.2'
    //compile 'com.google.code.gson:gson:2.8.0'
    //testCompile group: 'junit', name: 'junit', version: '4.11'
}