PausableOz.sol

pragma solidity 0.5.17;

import "./Ownable.sol";

contract PausableOz is Ownable {
    /**
     * @dev Emitted when the pause is triggered by the owner (`account`).
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by the owner (`account`).
     */
    event Unpaused(address account);

    bool internal _paused;

    constructor() internal {}

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view returns (bool) {
        return _paused;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     */
    modifier whenNotPaused() {
        require(!_paused, "Pausable: paused");
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     */
    modifier whenPaused() {
        require(_paused, "Pausable: not paused");
        _;
    }

    /**
     * @dev Called by the owner to pause, triggers stopped state.
     */
    function pause() public onlyOwner whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Called by the owner to unpause, returns to normal state.
     */
    function unpause() public onlyOwner whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}