build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
	id 'com.github.johnrengelman.shadow' version '8.1.1'
	id 'maven-publish'
	id 'eclipse'
	id 'java'
}

compileJava {
    sourceCompatibility = '21'
    targetCompatibility = '21'
}

repositories {
	mavenCentral()

	// Spigot
	maven {
		url 'https://repo.papermc.io/repository/maven-public/'
	}

	// Bungeecord
	maven {
		url "https://oss.sonatype.org/content/repositories/snapshots/"
	}

	// Skript
	maven {
		url 'https://repo.skriptlang.org/releases'
	}

}

dependencies {

	//Nullable annotation
	implementation (group: 'org.eclipse.jdt', name: 'org.eclipse.jdt.annotation', version: '2.2.700')

	//Spigot/Bukkit
	implementation (group: 'io.papermc.paper', name: 'paper-api', version: '1.20.6-R0.1-SNAPSHOT')

	//Skript
	implementation (group: 'com.github.SkriptLang', name: 'Skript', version: '2.7.2') {
		transitive = false
	}

	shadow group: 'org.bstats', name: 'bstats-bukkit', version: '3.0.2'

	shadow (group: 'org.json', name: 'json', version: '20230618')

}

processResources {
	filter ReplaceTokens, tokens: ["version": project.property("version")]
	from ('lang') {
        include '**/*'
        into 'lang/'
    }
    from ('documentation') {
        into 'documentation/'
    }
}

shadowJar {
	configurations = [project.configurations.shadow]
	dependencies {
		include(dependency('org.bstats:bstats-bukkit'))
		include(dependency('org.bstats:bstats-base'))
	}
	relocate 'org.bstats', 'com.w00tmast3r.skquery.bstats'
	archiveVersion = version
	archiveFileName = project.name + "-" + version + ".jar"
	minimize()
}