build.gradle

plugins {
    id 'java'
    id 'org.sonarqube' version '3.3'
    id 'jacoco'
    id 'info.solidsoft.pitest' version '1.7.0'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
}

group 'com.nelkinda.training'
version '0.0.1-SNAPSHOT'

sourceCompatibility = 17

repositories {
    mavenCentral()
}

dependencyManagement {
    dependencies {
        dependencySet(group: 'io.cucumber', version: '7.3.4') {
            entry 'cucumber-java'
            entry 'cucumber-junit-platform-engine'
        }
        dependencySet(group: 'org.junit.jupiter', version: '5.8.2') {
            entry 'junit-jupiter'
            entry 'junit-jupiter-api'
            entry 'junit-jupiter-engine'
            entry 'junit-jupiter-params'
        }
        dependencySet(group: 'org.junit.platform', version: '1.8.2') {
            entry 'junit-platform-commons'
            entry 'junit-platform-engine'
            entry 'junit-platform-launcher'
            entry 'junit-platform-suite-api'
            entry 'junit-platform-suite-commons'
            entry 'junit-platform-suite-engine'
        }
        dependencySet(group: 'org.mockito', version: '4.5.1') {
            entry 'mockito-core'
            entry 'mockito-inline'
        }
        dependency 'org.pitest:pitest-junit5-plugin:0.15'
        dependency 'org.pitest:pitest-command-line:1.8.0'
        dependency 'org.projectlombok:lombok:1.18.22'
    }
}
dependencies {
    annotationProcessor 'org.projectlombok:lombok'
    compileOnly 'org.projectlombok:lombok'

    testAnnotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'

    testImplementation 'io.cucumber:cucumber-java'
    testImplementation 'io.cucumber:cucumber-junit-platform-engine'
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testImplementation 'org.junit.jupiter:junit-jupiter-api'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine'
    testImplementation 'org.junit.jupiter:junit-jupiter-params'
    testImplementation 'org.junit.platform:junit-platform-commons'
    testImplementation 'org.junit.platform:junit-platform-engine'
    testImplementation 'org.junit.platform:junit-platform-suite-api'
    testImplementation 'org.junit.platform:junit-platform-suite-commons'
    testImplementation 'org.junit.platform:junit-platform-suite-engine'
    testImplementation 'org.mockito:mockito-core'
    testImplementation 'org.mockito:mockito-inline'

    pitest 'org.pitest:pitest-junit5-plugin'
    pitest 'org.pitest:pitest-command-line'
}

jacoco {
    toolVersion = "0.8.7"
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            limit {
                minimum = 0.0
            }
        }
    }
}
check.dependsOn jacocoTestCoverageVerification

jacocoTestReport {
    reports {
        xml.enabled true
        csv.enabled true
        html.enabled true
    }
}
test.finalizedBy jacocoTestReport

pitest {
    targetClasses.set(['com.nelkinda.training.*'])
    pitestVersion.set('1.8.0')
    timestampedReports.set(false)
    testPlugin.set('junit5')
    outputFormats.set(['XML', 'HTML'])
    mutators.set(['DEFAULTS', 'STRONGER', 'CONSTRUCTOR_CALLS', 'INLINE_CONSTS', 'REMOVE_CONDITIONALS', 'REMOVE_INCREMENTS'])
    mutationThreshold.set(100)
    coverageThreshold.set(100)
}

test {
    useJUnitPlatform()
}

wrapper {
    gradleVersion '7.4.2'
    distributionType = Wrapper.DistributionType.ALL
}