Calling a function from external library behaves differently

[Apis035]

I'm trying to use raylib in Adept as a dynamic link library. Below I attached a snippet of Adept code and equivalent C code for comparison.

Both does the following:

• Creating a window
• Enter the main loop, break if esc button is pressed
• Clear window screen with a color
• Draw FPS on the top left

However, on Adept, ClearBackground() behaves differently from the C code. It is expected to clear the window with a gray color, but instead it uses dark red color, as if the function reads only the red field from the color struct (record).

Question: How to fix this? Is the data type incorrect?

Test files: https://apis.s-ul.eu/j3HQICre

---

Adept code:

foreign 'raylib.dll'

record Color(r, g, b, a ubyte)

foreign InitWindow(int, int, *ubyte) void
foreign CloseWindow() void
foreign WindowShouldClose() bool
foreign SetTargetFPS(int) void
foreign BeginDrawing() void
foreign EndDrawing() void
foreign ClearBackground(Color) void
foreign DrawFPS(int, int) void

func main {
    color Color = Color(50, 50, 50, 255)

    InitWindow(800, 400, 'raylib - Adept')
    SetTargetFPS(60)
    until WindowShouldClose() {
        BeginDrawing()
        ClearBackground(color)
        DrawFPS(16, 16)
        EndDrawing()
    }
    CloseWindow()
}

C code:

#define RLAPI __declspec(dllimport)

typedef struct {unsigned char r, g, b, a;} Color;

RLAPI void InitWindow(int, int, char*);
RLAPI void CloseWindow();
RLAPI int  WindowShouldClose();
RLAPI void SetTargetFPS(int);
RLAPI void BeginDrawing();
RLAPI void EndDrawing();
RLAPI void ClearBackground(Color);
RLAPI void DrawFPS(int, int);

int main() {
    Color color = {50, 50, 50, 255};

    InitWindow(800, 400, "raylib - C");
    SetTargetFPS(60);
    while (!WindowShouldClose()) {
        BeginDrawing();
        ClearBackground(color);
        DrawFPS(16, 16);
        EndDrawing();
    }
    CloseWindow();
}

Result:

gcc main.c raylib.dll
./a

adept -e

[IsaacShelton]

That's weird, it should work the same.

I will see if I can reproduce it

[IsaacShelton]

It works as expected with adept -Onothing, so LLVM optimizations are somehow the culprit

[IsaacShelton]

It turns out that the LLVM C calling convention doesn't properly work when passing some struct types by value.

In the meantime, the following works:

foreign 'raylib.dll'

record Color(r, g, b, a ubyte)

foreign InitWindow(int, int, *ubyte) void
foreign CloseWindow() void
foreign WindowShouldClose() int
foreign SetTargetFPS(int) void
foreign BeginDrawing() void
foreign EndDrawing() void
foreign ClearBackground(int) void
foreign DrawFPS(int, int) void

func ClearBackground(color Color) {
    ClearBackground(*cast *int &color)
}

func main {
    color Color = Color(50, 50, 50, 255)

    InitWindow(800, 400, 'raylib - Adept')
    SetTargetFPS(60)
    until WindowShouldClose() {
        BeginDrawing()
        ClearBackground(color)
        DrawFPS(16, 16)
        EndDrawing()
    }
    CloseWindow()
}

[Apis035]

Thanks! It is a bit inconvenient but at least it works.
Looking forward for the proper fix on the compiler, as I might encounter similar issue on another scenario.