build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
}

group = 'me.xpyex'
version = '1.0.14'
def pluginPackage = 'me.xpyex.plugin.CnUsername'.toLowerCase()
def modulePackage = 'me.xpyex.module.CnUsername'.toLowerCase()

repositories {
    mavenCentral()
    maven {
        name = 'spigotmc-repo'
        url = 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/'
    }
    maven {
        name = 'sonatype'
        url = 'https://oss.sonatype.org/content/groups/public/'
    }
}

dependencies {
    compileOnly 'org.spigotmc:spigot-api:1.18.2-R0.1-SNAPSHOT'
    compileOnly 'net.md-5:bungeecord-api:1.19-R0.1-SNAPSHOT'
    implementation 'org.ow2.asm:asm:9.7'
}

def targetJavaVersion = 11
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

jar {
    manifest {
        attributes(
                "Premain-Class": modulePackage + '.CnUsername'
        )
    }
}

processResources {
    def props = [version: version, bc: (pluginPackage + '.bungee.CnUsernameBC'), bk: (pluginPackage + '.bukkit.CnUsernameBK')]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
    filesMatching('bungee.yml') {
        expand props
    }
    filesMatching('version') {
        expand props
    }
}

shadowJar {
    relocate 'org.objectweb.asm', 'me.xpyex.module.cnusername.libs.asm'
}